sys-apps/flashrom: add 1.3.0

With thanks to Anastasia Klimchuk <aklm@chromium.org> for the first bit
of shell code generating the list of programmers to enable.

Signed-off-by: Marek Szuba <marecki@gentoo.org>

3 files changed, 130 insertions, 1 deletions

diff --git a/sys-apps/flashrom/Manifest b/sys-apps/flashrom/Manifest
index 4490f56199e5..d7c6f0d73b6d 100644
--- a/sys-apps/flashrom/Manifest
+++ b/sys-apps/flashrom/Manifest
@@ -1,2 +1,3 @@
 DIST flashrom-v1.2.1.tar.bz2 365512 BLAKE2B d0eb2446ed0f0a952ae18296c5b4cbe72760cdf534d4bdc88255752c2ad1a4a503c7c5154493ba2c4dc042d31ca98359db3609a114536423d7a84af6a50fe1c7 SHA512 9cf4b9f69dd19364015fed49d411069ec6683455c90ebc3d102853825e0c46ccdaac30e78172f7cec5d2d15916efcd5ae12529d4e1ddc55efe705efecf3c0f40
 DIST flashrom-v1.2.tar.bz2 366995 BLAKE2B 091e01a91e12b486154ace334a5e74bccbb5f5311ad76e37f43a28167080757873d8c78b8f549d2e77eb984922c830895ba955b23eb6ee4fc24f1ffed259954b SHA512 8e01395a54d0d1344bc55e7e4975f43bb8e59ebe83fb5f2766d14f76756d718b487254ce9a19ef4093aed04fb9d40fff5fe8f709b18c512f6e6fad894f83d7b8
+DIST flashrom-v1.3.0.tar.bz2 489782 BLAKE2B e6d2284d83171b003b434251f060fa44edf32ecfd3d397bd4ba39b74c6a0b5c9d1659b703dd6b632b63aa4bf27d08c8aeece72920199712c6a4ae160b2eb3a8a SHA512 73b6e00bd3bc66c98d4ad53966a65b19d3d92f07d7b210d69e041d6f5788605b9791a9bf7aec0a52e13d19fcb62c4bdaf4bab9f805fc31468393ca313129a77b
diff --git a/sys-apps/flashrom/flashrom-1.3.0.ebuild b/sys-apps/flashrom/flashrom-1.3.0.ebuild
new file mode 100644
index 000000000000..14e290966f1b
--- /dev/null
+++ b/sys-apps/flashrom/flashrom-1.3.0.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+MY_P="${PN}-v${PV}"
+SRC_URI="https://download.flashrom.org/releases/${MY_P}.tar.bz2"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="Utility for reading, writing, erasing and verifying flash ROM chips"
+HOMEPAGE="https://flashrom.org/Flashrom"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+# The defaults should match the upstream "default" flags in meson.build
+IUSE_PROGRAMMERS="
+	atahpt
+	atapromise
+	+atavia
+	+buspirate-spi
+	+ch341a-spi
+	+dediprog
+	+developerbox-spi
+	+digilent-spi
+	+dirtyjtag-spi
+	+drkaiser
+	+dummy
+	+ft2232-spi
+	+gfxnvidia
+	+internal
+	+it8212
+	jlink-spi
+	+linux-mtd
+	+linux-spi
+	mediatek-i2c-spi
+	mstarddc-spi
+	+nic3com
+	+nicintel
+	+nicintel-eeprom
+	+nicintel-spi
+	nicnatsemi
+	+nicrealtek
+	+ogp-spi
+	parade-lspcon
+	+pickit2-spi
+	+pony-spi
+	+raiden-debug-spi
+	+rayer-spi
+	realtek-mst-i2c-spi
+	+satamv
+	+satasii
+	+serprog
+	+stlinkv3-spi
+	+usbblaster-spi"
+IUSE="${IUSE_PROGRAMMERS} +internal-dmi test tools"
+
+RESTRICT="!test? ( test )"
+
+COMMON="atahpt? ( sys-apps/pciutils )
+	atapromise? ( sys-apps/pciutils )
+	atavia? ( sys-apps/pciutils )
+	ch341a-spi? ( virtual/libusb:1 )
+	dediprog? ( virtual/libusb:1 )
+	developerbox-spi? ( virtual/libusb:1 )
+	digilent-spi? ( virtual/libusb:1 )
+	dirtyjtag-spi? ( virtual/libusb:1 )
+	drkaiser? ( sys-apps/pciutils )
+	ft2232-spi? ( dev-embedded/libftdi:1= )
+	gfxnvidia? ( sys-apps/pciutils )
+	internal? ( sys-apps/pciutils )
+	it8212? ( sys-apps/pciutils )
+	jlink-spi? ( dev-embedded/libjaylink )
+	nic3com? ( sys-apps/pciutils )
+	nicintel? ( sys-apps/pciutils )
+	nicintel-eeprom? ( sys-apps/pciutils )
+	nicintel-spi? ( sys-apps/pciutils )
+	nicnatsemi? ( sys-apps/pciutils )
+	nicrealtek? ( sys-apps/pciutils )
+	ogp-spi? ( sys-apps/pciutils )
+	pickit2-spi? ( virtual/libusb:1 )
+	raiden-debug-spi? ( virtual/libusb:1 )
+	satamv? ( sys-apps/pciutils )
+	satasii? ( sys-apps/pciutils )
+	stlinkv3-spi? ( virtual/libusb:1 )
+	usbblaster-spi? ( dev-embedded/libftdi:1= )"
+RDEPEND="${COMMON}
+	!internal-dmi? ( sys-apps/dmidecode )"
+DEPEND="${COMMON}
+	sys-apps/diffutils
+	linux-mtd? ( sys-kernel/linux-headers )
+	linux-spi? ( sys-kernel/linux-headers )
+	mediatek-i2c-spi? ( sys-kernel/linux-headers )
+	mstarddc-spi? ( sys-kernel/linux-headers )
+	parade-lspcon? ( sys-kernel/linux-headers )
+	realtek-mst-i2c-spi? ( sys-kernel/linux-headers )"
+BDEPEND="test? ( dev-util/cmocka )"
+
+DOCS=( README Documentation/ )
+
+src_configure() {
+	local programmers="$(printf '%s,' $(for flag in ${IUSE_PROGRAMMERS//+/}; do usev ${flag}; done))"
+	programmers="${programmers%,}"
+	programmers="${programmers//-/_}"
+	local emesonargs=(
+		-Dclassic_cli="enabled"
+		-Dprogrammer="${programmers}"
+		$(meson_feature test tests)
+		$(meson_feature tools ich_descriptors_tool)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use tools; then
+		dosbin "${BUILD_DIR}"/util/ich_descriptors_tool/ich_descriptors_tool
+	fi
+}
diff --git a/sys-apps/flashrom/metadata.xml b/sys-apps/flashrom/metadata.xml
index 5d3f570f6a38..6f60f84bb3d6 100644
--- a/sys-apps/flashrom/metadata.xml
+++ b/sys-apps/flashrom/metadata.xml
@@ -14,6 +14,7 @@
 		<flag name="dediprog">Dediprog SF100 support</flag>
 		<flag name="developerbox-spi">Enable Devloperbox SPI recovery support</flag>
 		<flag name="digilent-spi">Enable support for Digilent iCEblink40 development board</flag>
+		<flag name="dirtyjtag-spi">Support for DirtyJTAG (a USB-JTAG firmware for STM32 MCUs)</flag>
 		<flag name="drkaiser">Enable Dr. Kaiser programmer</flag>
 		<flag name="dummy">Enable dummy tracing</flag>
 		<flag name="ft2232-spi">Enable ftdi programmer, flashing through FTDI/SPI USB interface</flag>
@@ -24,6 +25,7 @@
 		<flag name="jlink-spi">Support for SEGGER J-Link and compatible devices</flag>
 		<flag name="linux-mtd">Enable support for Linux mtd SPI flash devices</flag>
 		<flag name="linux-spi">Enable support for Linux userspace spidev interface</flag>
+		<flag name="mediatek-i2c-spi">Support for Mediatek LCD controllers</flag>
 		<flag name="mstarddc-spi">Support for SPI flash ROMs accessible through DDC in MSTAR-equipped displays</flag>
 		<flag name="nic3com">Enable 3Com NIC programmer</flag>
 		<flag name="nicintel">Support for Intel NICs</flag>
@@ -32,9 +34,12 @@
 		<flag name="nicnatsemi">Support for National Semiconductor NICs</flag>
 		<flag name="nicrealtek">Support for Realtek NICs</flag>
 		<flag name="ogp-spi">Enable support for OGP (Open Graphics Project) SPI flashing</flag>
-		<flag name="pickit2-spi">SUpport for SPI flash ROMs accessible via Microchip PICkit2</flag>
+		<flag name="parade-lspcon">Enable support for Parade lspcon USB-C to HDMI protocol translator</flag>
+		<flag name="pickit2-spi">Support for SPI flash ROMs accessible via Microchip PICkit2</flag>
 		<flag name="pony-spi">Enable support for SI-Prog like hardware by Lancos</flag>
+		<flag name="raiden-debug-spi">Support for Chrome EC based debug tools - SuzyQable, Servo V4, C2D2 &amp; uServo</flag>
 		<flag name="rayer-spi">RayeR SPIPGM hardware support</flag>
+		<flag name="realtek-mst-i2c-spi">Enable support for Realtek RTD2142 MST</flag>
 		<flag name="satamv">Enable programmer for Marvell SATA controllers</flag>
 		<flag name="satasii">Enable programmer for SiI SATA controllers</flag>
 		<flag name="stlinkv3-spi">Enable SPI programmer using STLINK-V3</flag>