sys-apps/heirloom-tools: respect CFLAGS

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Closes: https://github.com/gentoo/gentoo/pull/15124
Signed-off-by: Stephan Hartmann <stha09@googlemail.com>
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 59 insertions, 0 deletions

diff --git a/sys-apps/heirloom-tools/heirloom-tools-070715-r2.ebuild b/sys-apps/heirloom-tools/heirloom-tools-070715-r2.ebuild
new file mode 100644
index 000000000000..f45cc2e1c880
--- /dev/null
+++ b/sys-apps/heirloom-tools/heirloom-tools-070715-r2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="Heirloom toolchest - original Unix tools"
+HOMEPAGE="http://heirloom.sourceforge.net/tools.html"
+SRC_URI="http://downloads.sourceforge.net/project/heirloom/heirloom/${PV}/heirloom-${PV}.tar.bz2"
+
+LICENSE="CDDL GPL-2 LGPL-2.1 9base ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	sys-libs/zlib
+"
+DEPEND="
+	${RDEPEND}
+	sys-apps/ed
+	sys-devel/bc
+	virtual/pkgconfig
+"
+S="${WORKDIR}/heirloom-${PV}"
+PATCHES=(
+	"${FILESDIR}"/${P}-major.patch
+	"${FILESDIR}"/${P}-glibc-2.30.patch
+	"${FILESDIR}"/${P}-glibc-2.31.patch
+	"${FILESDIR}"/${P}-gcc-10.patch
+)
+
+# slightly broken
+RESTRICT="test"
+
+src_compile() {
+	append-cppflags -D_GNU_SOURCE
+	emake -j1 \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		CFLAGS2="${CFLAGS}" \
+		CFLAGSS="${CFLAGS}" \
+		CFLAGSU="${CFLAGS}" \
+		CPPFLAGS="${CPPFLAGS}" \
+		LCURS="$( $(tc-getPKG_CONFIG) --libs ncurses)" \
+		LDFLAGS="${LDFLAGS}" \
+		LIBZ=-lz
+}
+
+src_install() {
+	# we don't want to strip here, so use "true" as noop
+	emake STRIP="true" ROOT="${D}" -j1 install
+}
+
+pkg_postinst() {
+	elog "You may want to add /usr/5bin or /usr/ucb to \$PATH"
+	elog "to enable using the apps of heirloom toolchest by default."
+	elog "Man pages are installed in /usr/share/man/5man/"
+	elog "You may need to set \$MANPATH to access them."
+}