sys-apps/i2c-tools: Version bump.

Package-Manager: Portage-2.3.18, Repoman-2.3.6

1 files changed, 62 insertions, 0 deletions

diff --git a/sys-apps/i2c-tools/i2c-tools-4.0.ebuild b/sys-apps/i2c-tools/i2c-tools-4.0.ebuild
new file mode 100644
index 000000000000..44fc1345dfa6
--- /dev/null
+++ b/sys-apps/i2c-tools/i2c-tools-4.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+DISTUTILS_OPTIONAL="1"
+
+inherit flag-o-matic multilib toolchain-funcs distutils-r1
+
+DESCRIPTION="I2C tools for bus probing, chip dumping, EEPROM decoding, and more"
+HOMEPAGE="https://www.kernel.org/pub/software/utils/i2c-tools"
+SRC_URI="${HOMEPAGE}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="!<sys-apps/lm_sensors-3
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+	use python && distutils-r1_src_configure
+}
+
+src_compile() {
+	emake all-lib CC=$(tc-getCC) # parallel make
+	emake CC=$(tc-getCC)
+	emake -C eepromer CC=$(tc-getCC)
+	if use python ; then
+		cd py-smbus || die
+		append-cppflags -I../include
+		distutils-r1_src_compile
+	fi
+}
+
+src_install() {
+	emake install libdir=$(get_libdir) prefix="${D}"/usr
+	dosbin eepromer/eeprom{,er}
+	rm -rf "${D}"/usr/include # part of linux-headers
+	dodoc CHANGES README
+	local d
+	for d in eeprom eepromer ; do
+		docinto ${d}
+		dodoc ${d}/README*
+	done
+
+	if use python ; then
+		cd py-smbus || die
+		docinto py-smbus
+		dodoc README*
+		distutils-r1_src_install
+	fi
+}