sys-apps/texinfo: Bump to version 6.5

Package-Manager: Portage-2.3.8, Repoman-2.3.3

1 files changed, 42 insertions, 0 deletions

diff --git a/sys-apps/texinfo/texinfo-6.5.ebuild b/sys-apps/texinfo/texinfo-6.5.ebuild
new file mode 100644
index 000000000000..6e53f592081e
--- /dev/null
+++ b/sys-apps/texinfo/texinfo-6.5.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+# Note: if your package uses the texi2dvi utility, it must depend on the
+# virtual/texi2dvi package to pull in all the right deps.  The tool is not
+# usable out-of-the-box because it requires the large tex packages.
+
+EAPI=6
+
+inherit flag-o-matic
+
+DESCRIPTION="The GNU info program and utilities"
+HOMEPAGE="https://www.gnu.org/software/texinfo/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE="nls static"
+
+RDEPEND="
+	!=app-text/tetex-2*
+	>=sys-libs/ncurses-5.2-r2:0=
+	dev-lang/perl:=
+	dev-perl/libintl-perl
+	dev-perl/Unicode-EastAsianWidth
+	dev-perl/Text-Unidecode
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	nls? ( >=sys-devel/gettext-0.19.6 )"
+
+src_configure() {
+	use static && append-ldflags -static
+	local myeconfargs=(
+		--with-external-libintl-perl
+		--with-external-Unicode-EastAsianWidth
+		--with-external-Text-Unidecode
+		$(use_enable nls)
+	)
+	econf "${myeconfargs[@]}"
+}