sys-auth/fprintd: bump to 1.92.0

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Marco Scardovi <marco@scardovi.com>
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 96 insertions, 0 deletions

diff --git a/sys-auth/fprintd/fprintd-1.92.0.ebuild b/sys-auth/fprintd/fprintd-1.92.0.ebuild
new file mode 100644
index 000000000000..db5a0d6162f2
--- /dev/null
+++ b/sys-auth/fprintd/fprintd-1.92.0.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit meson pam python-any-r1 systemd
+
+MY_P="${PN}-v${PV}"
+
+DESCRIPTION="D-Bus service to access fingerprint readers"
+HOMEPAGE="https://gitlab.freedesktop.org/libfprint/fprintd"
+SRC_URI="https://gitlab.freedesktop.org/libfprint/${PN}/-/archive/v${PV}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~sparc ~x86"
+IUSE="doc pam systemd test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/dbus-glib
+	dev-libs/glib:2
+	sys-auth/libfprint:2
+	sys-auth/polkit
+	pam? (
+		sys-libs/pam
+		systemd? ( sys-apps/systemd )
+		!systemd? ( sys-auth/elogind )
+	)"
+
+DEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_any_dep '
+			dev-python/python-dbusmock[${PYTHON_USEDEP}]
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+			dev-python/pycairo[${PYTHON_USEDEP}]
+			pam? ( sys-libs/pam_wrapper[${PYTHON_USEDEP}] )
+		')
+	)"
+
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig
+	doc? (
+		dev-libs/libxml2
+		dev-libs/libxslt
+		dev-util/gtk-doc
+	)"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.90.7_0001-add-test-feature-and-make-tests-optional.patch"
+	"${FILESDIR}/${PN}-1.90.8_0002-add-configure-option-for-libsystemd-provider.patch"
+)
+
+S="${WORKDIR}/${MY_P}"
+
+python_check_deps() {
+	if use test; then
+		has_version -d "sys-libs/pam_wrapper[${PYTHON_USEDEP}]"
+	fi
+	has_version -d "dev-python/dbusmock[${PYTHON_USEDEP}]" &&
+	has_version -d "dev-python/dbus-python[${PYTHON_USEDEP}]" &&
+	has_version -d "dev-python/pycairo[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+		local emesonargs=(
+			$(meson_feature test)
+			$(meson_use pam)
+			-Dgtk_doc=$(usex doc true false)
+			-Dman=true
+			-Dsystemd_system_unit_dir=$(systemd_get_systemunitdir)
+			-Dpam_modules_dir=$(getpam_mod_dir)
+			-Dlibsystemd=$(usex systemd libsystemd libelogind)
+		)
+		meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	dodoc AUTHORS NEWS README TODO
+	newdoc pam/README README.pam_fprintd
+}
+
+pkg_postinst() {
+	elog "Please take a look at README.pam_fprintd for integration docs."
+}