sys-block/open-isns: Bump to version 0.99

Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/sys-block/open-isns/open-isns-0.99.ebuild b/sys-block/open-isns/open-isns-0.99.ebuild
new file mode 100644
index 000000000000..e9c2b890b984
--- /dev/null
+++ b/sys-block/open-isns/open-isns-0.99.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic
+
+DESCRIPTION="iSNS server and client for Linux"
+HOMEPAGE="https://github.com/open-iscsi/open-isns"
+SRC_URI="https://github.com/open-iscsi/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug libressl slp ssl static"
+
+DEPEND="
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	slp? ( net-libs/openslp )"
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}/${PN}-0.98-libressl-compatibility.patch" )
+
+src_configure() {
+	use debug && append-cppflags -DDEBUG_TCP -DDEBUG_SCSI
+	append-lfs-flags
+	local myeconfargs=(
+		 $(use_with slp)
+		$(use_with ssl security)
+		$(use_enable !static shared)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	emake DESTDIR="${D}" install_hdrs
+	emake DESTDIR="${D}" install_lib
+	keepdir /var/lib/${PN/open-}
+	if ! use static ; then
+		find "${ED}" -type f -name "*.a" -delete || die
+	fi
+}