sys-kernel/gentoo-kernel-bin: bump to 5.4.134-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 115 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index c340f148bcad..1e71190acdf5 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -89,6 +89,7 @@ DIST gentoo-kernel-5.4.133-1.amd64.xpak 61363527 BLAKE2B 70c1bc3b3c1b28063543947
 DIST gentoo-kernel-5.4.133-1.arm64.xpak 56119242 BLAKE2B ab692e9712c3280b421584132ad019c8670a917f988560962c6171946e4aca644c095f37ec6886fab718f1360a95bf8d0bf18d36b98ca8ded4c6c03b1cac4f45 SHA512 01450071b0f5e72e50a17e488b44d0b9108b0e46fc5816f14caed0136bc42970a1c0f5a0c1b1d99ab7b0c17e9d0dba6bee05428473271b5233bf579cd9afd079
 DIST gentoo-kernel-5.4.133-1.x86.xpak 53153541 BLAKE2B 32199c6960e729ce93277c6c720b3d43afdaf58093d5cd831b338d924a27e0302d4a55f2d7c52e0594a81bea8f25a4e1cea34b5beb23a9c460edd5835696a13b SHA512 da0b897d1bd8b068894913fafeffded9da23b81c7017fd5eb850462660c68badce615c1a625a38e2e4e4c607190f0976b967f76184a1dbf11ffe73241d05baef
 DIST gentoo-kernel-5.4.134-1.amd64.xpak 61349154 BLAKE2B c7627b1a8ad85b22450ae1b47a26f9144707f8a2173b01859ea1d876cf4d96e9fcc27be439e6c0239d7494795cc62fa931ecc71be84f9f898ec017a79d82dcf9 SHA512 d4c6613ed069a0ec2dbb5f5bb317abe952309f6ba6fbb163cbf1392478b1756dd129e51665b3b4e9c939395f5cdbc553003d7f0201098f959be9d29233a48cc9
+DIST gentoo-kernel-5.4.134-1.arm64.xpak 56052116 BLAKE2B 6a901fb6a639470145c8b58e435cfe4a380ebd402397ca34eace732936fda8e38a8e92e0f49d747e6f1ae8fb5410960e236ea2cc22dbc7f25ac833275b9b6fea SHA512 216287843b7d1e740afa3c88376e5d5ae99d88882b6669c753fdd341d7f9cd84ee8cbf28fb08f6101b9a9263ce20c6ddeeececf078c7387e571eac53baa52204
 DIST gentoo-kernel-5.4.134-1.x86.xpak 53144418 BLAKE2B d11e4de3fddb270cc41c9ad49c048df0af8e578f9ef0d811dbc4d930c7b399b7bfff724db889e3e8ce9332920b5f736594923646f7c1c8eb9f07371a85f0a1c9 SHA512 7fc2a72b5f7b636312ff28a2beb07a4514093499bb498bd43574cfd5178490c94628391acfb0da1c08569cbe0cc629373a1b9828398418f82c1745961c6508e1
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.12.tar.xz 118112412 BLAKE2B 842d921b9a73d2aaade763dbd2ec67bdfe0275baa6d628b775f5c87574ad7dc86f0419afcd48c10c1235f4bffa16084243f2cf4556e6afcd391e975fe8ba530b SHA512 be03b6fee1d1ea8087b09874d27c0a602c0b04fd90ad38b975bd2c8455a07e83c29b56814aaf1389e82305fae0e4c2d1701075a7f0a7295dd28149f967ec5b3d
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.134-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.134-r1.ebuild
new file mode 100644
index 000000000000..b63276300c50
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.134-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}