sys-kernel/gentoo-kernel-bin: add 5.4.161-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index c45d584b7818..3dbddee059cf 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -47,6 +47,7 @@ DIST gentoo-kernel-5.4.160-1.amd64.xpak 61419703 BLAKE2B 82b6f04cd1d7c2485b1fad1
 DIST gentoo-kernel-5.4.160-1.arm64.xpak 57566747 BLAKE2B b95f9665af8b8b29263eca4d0efeb4c4738c565cd5cc82077690182a2f341246037b039ad918f0f33ae770f5b375c486e523c9feb3615069e36e4e59c29311d6 SHA512 041a84459e784973f734ff0aa591f218b80c3e19301a284ea70a7e910d0103848221aa60a7b4d0da5e54d300063edb190ede1caaafeebed2367426db3aa6cc09
 DIST gentoo-kernel-5.4.160-1.x86.xpak 53205051 BLAKE2B 9b67b07cb0b05d8f68d958432a427e7a903ff1a63b14b4d168f6d3ece28775a1042d8f8959e37cc4176123e7c9cafeb925fcb1bad0371af54aa7a4db90ad42a2 SHA512 d9711bcb40751af6c2aaad8888e8169e36f2b35492c867fe572c9901d91d05089fd1f43e6f5d4a39b70e8e540a5877cebf1edd834b4f952484f8fbd4b9cdd103
 DIST gentoo-kernel-5.4.161-1.amd64.xpak 61397959 BLAKE2B 9b213988ec360726a154c855355116fe118ac2350df7f0ef1349ca16ac6de5cf61ba3ec414e6b4f862fd1fb4b3942fd6bb6c43c707b436e7a49f0936da4b0c4c SHA512 a604e7e6520a34af6f2033d62602707cc1be5d5aebbc598ec068b1be7e841b43ffc8ede98cbc19a62a8b07eeb40b7951567144f5a6a0ec118460c8be302864c3
+DIST gentoo-kernel-5.4.161-1.arm64.xpak 57696274 BLAKE2B e2c6edf9cec49fe7715b5a2f92266367a64af9be9aa5f25fcdda1ac69f2ba3bbb19c6b45420d3a39053ddd5d1bc9aa30c079c5c8a87f5ce62b12ffe889238721 SHA512 a4bfcbb83267e78f6e52fca130fc3e0aacbedca6b91594d22d083431c4cf92b0fb8e2f85647438c7f1bc94cc0253f9c9f6e3cffbadfc99aeec5fe9aac177a1fe
 DIST gentoo-kernel-5.4.161-1.x86.xpak 53165081 BLAKE2B 9bc7c8f2fe7754630edbf9f6df30912e435d9118395b529d732c12b1b1549815810df2e0714476bd4e545311b2c474b9258ebfe293b20dda338e92e3feb3e5ef SHA512 9e1d201483befe38604bbb06ffb5a27da4a643a648bb7d732470007eddde22766f9934cdb2a3bee81d5bfe213d13c7f776708ce8a5b7900b5a4e3f2431c9cd59
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.13.tar.xz 119297284 BLAKE2B 9c4c12e2394dec064adff51f7ccdf389192eb27ba7906db5eda543afe3d04afca6b9ea0848a057571bf2534eeb98e1e3a67734deff82c0d3731be205ad995668 SHA512 a8edf97e9d38a49f1be2bde1e29ad96274bb2c6f7e8a2bebaa1161dd4df9cabcbaec4ff644c45bee94f86ae47725087d6deed0cd954209cec717621d137db85e
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.161-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.161-r1.ebuild
new file mode 100644
index 000000000000..fe6e6023d323
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.161-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}