sys-kernel/gentoo-kernel-bin: add 5.4.150-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 382139e761ac..63e7b48138ec 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -44,6 +44,7 @@ DIST gentoo-kernel-5.4.149-1.amd64.xpak 61361096 BLAKE2B d6878e37659f587c3adcb64
 DIST gentoo-kernel-5.4.149-1.arm64-r1.xpak 58015698 BLAKE2B 46f0c4da592df3cb7082e9669c5c27818a9fc139bf64e7df95804d7c814326dc1a85fc7ced061b1f3924412ba88e5a20551655639ea515832cf388f16a57c772 SHA512 2d3a78e2a7319163ced95e8d16ea1ee1aa25fc071539e1f0b7a0f3a7b86e587aa9bf20d369e2e0ad8c67937d21514c60d9d145e1b56084c2e555ec4fd9c81072
 DIST gentoo-kernel-5.4.149-1.x86.xpak 53165112 BLAKE2B a4776fd1b202800147146896a97a35a137b006bad285fa29dd5be02507024057acfe5b3e9909c89d00037add03177e4202c671e951a384f91f1d57673ccaf704 SHA512 344e2054cfcff49a32fa3baa76f92076377832987a6f109bc33f518bf06c6b714edf3fce62ade100dd4775c2ddbdde98db1eb22e672388a95f6c45b964f0495e
 DIST gentoo-kernel-5.4.150-1.amd64.xpak 61393974 BLAKE2B 67149f1daa5c41fc6e31fc14a88cc91200acf3f0a0d002ae8abed00eddb351db22814cb3c6fcf90ea563e0acb46de7ea7c02f9a1654ad4966355da51615b6805 SHA512 f9bcbd1c4eeacb7c247179b239992508a192582d6d463a1ffe4820faeb0931f91239cf6eb88ba3cbcf09e6f9c2fd414ef3ebaab7cc9ec2aba50b5d4ce365b7e5
+DIST gentoo-kernel-5.4.150-1.arm64-r1.xpak 58016119 BLAKE2B 325908bb5c23ffdefcbbcdfcbfaf9893f4d7819c543830a5fbb2fd60541cda3397ca654dd7d0e19072ec39a29deeb7e6757fd29cd80d86f77519ae32eef2e624 SHA512 5ddca7faf121649d29e9ee2e9c005f199a26e2efcceaae8f5eb0ef24474b24476eed3c62b709ed0f6412c918fc7ffc5d50c46ddcefc838872df98d374dae171d
 DIST gentoo-kernel-5.4.150-1.x86.xpak 53154582 BLAKE2B 3230b498ed602da9cab50d62b24b3b36eadaf32931b5d305473a2d73260c4870bcc60fa2859370c22365e2b18a209f616450c67cd81e6839990e5e00fb2da746 SHA512 cdb588a6ba0a76b77ff9f1bcaf7dbdf36d36dd24ab91817192f8f16e3a4d28c9ad8d1dac36146595383edc721f3268a4e2bb666e1ce4c0e29a24fa9a24f95ee2
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.13.tar.xz 119297284 BLAKE2B 9c4c12e2394dec064adff51f7ccdf389192eb27ba7906db5eda543afe3d04afca6b9ea0848a057571bf2534eeb98e1e3a67734deff82c0d3731be205ad995668 SHA512 a8edf97e9d38a49f1be2bde1e29ad96274bb2c6f7e8a2bebaa1161dd4df9cabcbaec4ff644c45bee94f86ae47725087d6deed0cd954209cec717621d137db85e
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.150-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.150-r1.ebuild
new file mode 100644
index 000000000000..3b97f74d1041
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.150-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64-r1.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}