sys-kernel/gentoo-kernel-bin: bump to 5.10.34 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 115 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 156bb78d8b9b..29d407bc9a0a 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -57,6 +57,7 @@ DIST gentoo-kernel-5.10.33-1.amd64.xpak 65526470 BLAKE2B 205070bff9d1a7f7e58a26f
 DIST gentoo-kernel-5.10.33-1.arm64.xpak 59313277 BLAKE2B db163fcb9b75ad919fa1aa329b653ecb82eabfae6e50a2f2a32aae8acc7c9802ff76f4c84fe1dd180f20511dd100d695c9c8e7db1e93f93a284b18061cb16fce SHA512 50f979a6314a4603a4f3bbc906fc4ac9d3854b666bcbe83e6a1c3b9209c33aff9fad4f291d491b8ce188f17188759703a2da665d170c317bb47d1ca283571976
 DIST gentoo-kernel-5.10.33-1.x86.xpak 57243809 BLAKE2B 209b1c49bb4d43ca73a438b021bee5274a003caf6c94fe1448f61bd39ba4ce6ddb021125b998e386edc16662c5266945c876b2ad4d5986f177088a2425a31895 SHA512 5399b3788dea2172112d3e52082bfd5a2120accf50acdd0a5a4897e495413b706a237c5f82ae6dd9a6e8a95c41aaa1f06c475043fa4c88bf81dac11b1fab79e9
 DIST gentoo-kernel-5.10.34-1.amd64.xpak 65503671 BLAKE2B 130669ba72a60ab46b5925a425cde7ce6ca9e4a6097bb07f579c237933c9e7d6c5515a66844eff947d2f7710a5ef3c3345b0f5c3fcb48475d13a4dacd82410e9 SHA512 4075bc549479915431eba85258b3614ca6a0809a069b2f595acbaf550be9ed0002b862fc7c10dcd87950e195da9c9bc455fa93182d42a67db276cafee662fb5d
+DIST gentoo-kernel-5.10.34-1.arm64.xpak 59370469 BLAKE2B 1f781b6a610a469a88dd1c8cc302b34a11c9b95d6c6b0eefdb2993af00fb8fb98a6eea86d010792b61b7b425079925a9e8c324091979290f607586f9b1bf14e9 SHA512 3bbf3e6b850d227be72602561dcc31f859ebcb85c9fbf89d7a024915c883ffb96ddbd34df85f4e3dbfea5b72126e79de006d05b32f6afcdab2fbe08a6e757b93
 DIST gentoo-kernel-5.10.34-1.x86.xpak 57242621 BLAKE2B 14d65a4c58ba3e115ec868dac865f1ccc44db854815b14a657b08d07de8a0e5ba37cff3f1546b6a033b0578bf1c8fcf7f55a7d37d6e14b1ebce1df92d78bab94 SHA512 b5c32babfbc891d0f7e1f4c6aa6ef18ae46819e2c65bec54123e62bea50a345888571ab26ef2c56455f81869554fdb1516e942ba77bca49d5861d9ae23a0914a
 DIST gentoo-kernel-5.11.13-1.amd64.xpak 64685029 BLAKE2B 7d6794c5fd15434d2ad93d36678476e4a6aa3ad9ff77140a0bc8d74b0c87155898e8f1f76dfd40f72c878d9ddca7b7f1a9f0d4be2a600c5e2c18a77a3439e9d5 SHA512 d8c0fb975ee35e6d71b3b255800179805c9e70bfa7ef5299a38145c6cfd4f60720281c70f2d16a409a10c4ee6c6f26ac2e0c3151b114ced91c747371b59885b0
 DIST gentoo-kernel-5.11.13-1.arm64.xpak 59816443 BLAKE2B f3bd4b929cd103f95b91f0c0f28f324f8e316e1cc4b310742d159b8dbdb6c288d9424984e0859873924ac7eb34f12278b2086ad48fbf11da955f0b390dfda619 SHA512 6aae6cd29857eb897a167e359f9628692803bb75a0a1f235468a1b95e9c2f3d9525f33d6673b5c12edb5d9feba29210a79d8030d151a5b7260119a81eef57e1d
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.34-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.34-r1.ebuild
new file mode 100644
index 000000000000..8198cf5ace09
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.34-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}