sys-libs/libcxxabi: Remove 13.0.1.9999

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 0 insertions, 125 deletions

diff --git a/sys-libs/libcxxabi/libcxxabi-13.0.1.9999.ebuild b/sys-libs/libcxxabi/libcxxabi-13.0.1.9999.ebuild
deleted file mode 100644
index d260ea2e3450..000000000000
--- a/sys-libs/libcxxabi/libcxxabi-13.0.1.9999.ebuild
+++ /dev/null
@@ -1,125 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-CMAKE_ECLASS=cmake
-PYTHON_COMPAT=( python3_{8..10} )
-inherit cmake-multilib llvm llvm.org python-any-r1 toolchain-funcs
-
-DESCRIPTION="Low level support for a standard C++ library"
-HOMEPAGE="https://libcxxabi.llvm.org/"
-
-LICENSE="Apache-2.0-with-LLVM-exceptions || ( UoI-NCSA MIT )"
-SLOT="0"
-KEYWORDS=""
-IUSE="+libunwind static-libs test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	libunwind? (
-		|| (
-			>=sys-libs/libunwind-1.0.1-r1[static-libs?,${MULTILIB_USEDEP}]
-			>=sys-libs/llvm-libunwind-3.9.0-r1[static-libs?,${MULTILIB_USEDEP}]
-		)
-	)"
-# llvm-6 for new lit options
-DEPEND="${RDEPEND}
-	>=sys-devel/llvm-6"
-BDEPEND="
-	test? ( >=sys-devel/clang-3.9.0
-		$(python_gen_any_dep 'dev-python/lit[${PYTHON_USEDEP}]')
-	)"
-
-LLVM_COMPONENTS=( libcxx{abi,} llvm/cmake )
-llvm.org_set_globals
-
-python_check_deps() {
-	has_version "dev-python/lit[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	# darwin prefix builds do not have llvm installed yet, so rely on bootstrap-prefix
-	# to set the appropriate path vars to LLVM instead of using llvm_pkg_setup.
-	if [[ ${CHOST} != *-darwin* ]] || has_version dev-lang/llvm; then
-		llvm_pkg_setup
-	fi
-	use test && python-any-r1_pkg_setup
-}
-
-multilib_src_configure() {
-	# we need a configured libc++ for __config_site
-	wrap_libcxx cmake_src_configure
-	wrap_libcxx cmake_build generate-cxx-headers
-
-	# link against compiler-rt instead of libgcc if we are using clang with libunwind
-	local want_compiler_rt=OFF
-	if use libunwind && tc-is-clang; then
-		local compiler_rt=$($(tc-getCC) ${CFLAGS} ${CPPFLAGS} \
-			${LDFLAGS} -print-libgcc-file-name)
-		if [[ ${compiler_rt} == *libclang_rt* ]]; then
-			want_compiler_rt=ON
-		fi
-	fi
-
-	local libdir=$(get_libdir)
-	local mycmakeargs=(
-		-DLIBCXXABI_LIBDIR_SUFFIX=${libdir#lib}
-		-DLIBCXXABI_ENABLE_SHARED=ON
-		-DLIBCXXABI_ENABLE_STATIC=$(usex static-libs)
-		-DLIBCXXABI_USE_LLVM_UNWINDER=$(usex libunwind)
-		-DLIBCXXABI_INCLUDE_TESTS=$(usex test)
-		-DLIBCXXABI_USE_COMPILER_RT=${want_compiler_rt}
-
-		-DLIBCXXABI_LIBCXX_INCLUDES="${BUILD_DIR}"/libcxx/include/c++/v1
-		# upstream is omitting standard search path for this
-		# probably because gcc & clang are bundling their own unwind.h
-		-DLIBCXXABI_LIBUNWIND_INCLUDES="${EPREFIX}"/usr/include
-		-DLIBCXXABI_TARGET_TRIPLE="${CHOST}"
-	)
-	if use test; then
-		local clang_path=$(type -P "${CHOST:+${CHOST}-}clang" 2>/dev/null)
-		[[ -n ${clang_path} ]] || die "Unable to find ${CHOST}-clang for tests"
-
-		mycmakeargs+=(
-			-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
-			-DLLVM_LIT_ARGS="$(get_lit_flags);--param=cxx_under_test=${clang_path}"
-			-DPython3_EXECUTABLE="${PYTHON}"
-		)
-	fi
-	cmake_src_configure
-}
-
-wrap_libcxx() {
-	local -x LDFLAGS="${LDFLAGS} -L${BUILD_DIR}/$(get_libdir)"
-	local CMAKE_USE_DIR=${WORKDIR}/libcxx
-	local BUILD_DIR=${BUILD_DIR}/libcxx
-	local mycmakeargs=(
-		-DLIBCXX_LIBDIR_SUFFIX=
-		-DLIBCXX_ENABLE_SHARED=OFF
-		-DLIBCXX_ENABLE_STATIC=ON
-		-DLIBCXX_ENABLE_EXPERIMENTAL_LIBRARY=OFF
-		-DLIBCXX_CXX_ABI=libcxxabi
-		-DLIBCXX_CXX_ABI_INCLUDE_PATHS="${S}"/include
-		-DLIBCXX_ENABLE_ABI_LINKER_SCRIPT=OFF
-		-DLIBCXX_HAS_MUSL_LIBC=$(usex elibc_musl)
-		-DLIBCXX_HAS_GCC_S_LIB=OFF
-		-DLIBCXX_INCLUDE_TESTS=OFF
-		-DLIBCXX_TARGET_TRIPLE="${CHOST}"
-	)
-
-	"${@}"
-}
-
-multilib_src_test() {
-	wrap_libcxx cmake_src_compile
-	mv "${BUILD_DIR}"/libcxx/lib/libc++* "${BUILD_DIR}/$(get_libdir)/" || die
-
-	local -x LIT_PRESERVES_TMP=1
-	cmake_build check-cxxabi
-}
-
-multilib_src_install_all() {
-	insinto /usr/include/libcxxabi
-	doins -r include/.
-}