sys-power/cpupower: add 5.12

Closes: https://github.com/gentoo/gentoo/pull/22108
Signed-off-by: Mike Gilbert <floppym@gentoo.org>

1 files changed, 66 insertions, 0 deletions

diff --git a/sys-power/cpupower/cpupower-5.12.ebuild b/sys-power/cpupower/cpupower-5.12.ebuild
new file mode 100644
index 000000000000..1676159b9393
--- /dev/null
+++ b/sys-power/cpupower/cpupower-5.12.ebuild
@@ -0,0 +1,66 @@
+# Copyright 2013-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit systemd toolchain-funcs
+
+DESCRIPTION="Shows and sets processor power related values"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI="https://cdn.kernel.org/pub/linux/kernel/v${PV%%.*}.x/linux-${PV}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0/0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="nls"
+
+# File collision w/ headers of the deprecated cpufrequtils
+RDEPEND="sys-apps/pciutils"
+DEPEND="${RDEPEND}
+	virtual/os-headers
+	nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}/cpupower-5.4-cflags.patch"
+)
+
+S="${WORKDIR}/linux-${PV}"
+
+src_configure() {
+	export bindir="${EPREFIX}/usr/bin"
+	export sbindir="${EPREFIX}/usr/sbin"
+	export mandir="${EPREFIX}/usr/share/man"
+	export includedir="${EPREFIX}/usr/include"
+	export libdir="${EPREFIX}/usr/$(get_libdir)"
+	export localedir="${EPREFIX}/usr/share/locale"
+	export docdir="${EPREFIX}/usr/share/doc/${PF}"
+	export confdir="${EPREFIX}/etc"
+	export bash_completion_dir="${EPREFIX}/usr/share/bash-completion/completions"
+	export V=1
+	export NLS=$(usex nls true false)
+}
+
+src_compile() {
+	myemakeargs=(
+		AR="$(tc-getAR)"
+		CC="$(tc-getCC)"
+		LD="$(tc-getCC)"
+		VERSION=${PV}
+	)
+
+	cd tools/power/cpupower || die
+	emake "${myemakeargs[@]}"
+}
+
+src_install() {
+	cd tools/power/cpupower || die
+	emake "${myemakeargs[@]}" DESTDIR="${D}" install
+	doheader lib/cpupower.h
+	einstalldocs
+
+	newconfd "${FILESDIR}"/conf.d-r2 cpupower
+	newinitd "${FILESDIR}"/init.d-r4 cpupower
+
+	systemd_dounit "${FILESDIR}"/cpupower-frequency-set.service
+	systemd_install_serviced "${FILESDIR}"/cpupower-frequency-set.service.conf
+}