sys-process/latencytop: Misc improvements

* EAPI=5 (not 6 per base-system requirement)
* kernel-info config checking
* KEYWORD="~arm" (tested on armv7a RK3288)
* Convert patches to -p1

Ack'ed by polynomial-c
Closes: https://github.com/gentoo/gentoo/pull/3293

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 53 insertions, 0 deletions

diff --git a/sys-process/latencytop/latencytop-0.5-r1.ebuild b/sys-process/latencytop/latencytop-0.5-r1.ebuild
new file mode 100644
index 000000000000..68205b18ef26
--- /dev/null
+++ b/sys-process/latencytop/latencytop-0.5-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils linux-info
+
+DESCRIPTION="tool for identifying where in the system latency is happening"
+HOMEPAGE="http://git.infradead.org/latencytop.git"
+
+# Upstream is long gone, so we explicitly use our mirrors for the tarball
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+
+CONFIG_CHECK="~LATENCYTOP"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="gtk"
+
+RDEPEND="dev-libs/glib:2
+	gtk? ( x11-libs/gtk+:2 )
+	sys-libs/ncurses:0="
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+# Upstream is dead, so there are no bugs to track for any
+# of these patches.
+PATCHES=(
+	"${FILESDIR}/${P}-01-mkdir-usr-sbin-as-well.patch"
+	"${FILESDIR}/${P}-03-clean-up-build-system.patch"
+	"${FILESDIR}/${P}-fsync-fix-implicit-decl.patch"
+)
+
+pkg_pretend() {
+	linux-info_pkg_setup
+}
+
+pkg_setup() {
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	epatch "${PATCHES[@]}"
+
+	# Without a configure script, we toggle bools manually
+	# This also needs to be done after patches are applied
+	# since this bool doesn't exist outside our patches
+	if ! use gtk; then
+		sed -i -e "/HAS_GTK_GUI = 1/d" Makefile || die
+	fi
+}