summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorTomas Mozes <hydrapolic@gmail.com>2018-09-17 12:47:56 +0200
committerMichał Górny <mgorny@gentoo.org>2018-09-28 11:44:32 +0200
commit712d3d3706f682c0f64895d2d2a17d5486093007 (patch)
tree5682db156d86adfbc054a44442d71638ae6a26a7 /www-apps
parentprofiles/releases/13.0: mask >=www-apps/kibana-bin-6 (diff)
downloadgentoo-712d3d3706f682c0f64895d2d2a17d5486093007.tar.gz
gentoo-712d3d3706f682c0f64895d2d2a17d5486093007.tar.bz2
gentoo-712d3d3706f682c0f64895d2d2a17d5486093007.zip
www-apps/kibana-bin: allow using newer node.js version
Closes: https://github.com/gentoo/gentoo/pull/9892 Signed-off-by: Tomáš Mózes <hydrapolic@gmail.com> Package-Manager: Portage-2.3.49, Repoman-2.3.10 Signed-off-by: Michał Górny <mgorny@gentoo.org>
Diffstat (limited to 'www-apps')
-rw-r--r--www-apps/kibana-bin/kibana-bin-6.4.0-r1.ebuild74
1 files changed, 74 insertions, 0 deletions
diff --git a/www-apps/kibana-bin/kibana-bin-6.4.0-r1.ebuild b/www-apps/kibana-bin/kibana-bin-6.4.0-r1.ebuild
new file mode 100644
index 00000000000..fda8f3b78d7
--- /dev/null
+++ b/www-apps/kibana-bin/kibana-bin-6.4.0-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit systemd user
+
+MY_PN="${PN%-bin}"
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Analytics and search dashboard for Elasticsearch"
+HOMEPAGE="https://www.elastic.co/products/kibana"
+SRC_URI="x-pack? ( https://artifacts.elastic.co/downloads/${MY_PN}/${MY_P}-linux-x86_64.tar.gz )
+ !x-pack? ( https://artifacts.elastic.co/downloads/${MY_PN}/${MY_PN}-oss-${PV}-linux-x86_64.tar.gz )"
+
+# source: LICENSE.txt and NOTICE.txt
+LICENSE="Apache-2.0 Artistic-2 BSD BSD-2 CC-BY-3.0 CC-BY-4.0 icu ISC MIT MPL-2.0 OFL-1.1 openssl public-domain Unlicense WTFPL-2 ZLIB x-pack? ( Elastic )"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="x-pack"
+
+RDEPEND=">=net-libs/nodejs-8.11.4"
+
+S="${WORKDIR}/${MY_P}-linux-x86_64"
+
+pkg_setup() {
+ enewgroup ${MY_PN}
+ enewuser ${MY_PN} -1 -1 /opt/${MY_PN} ${MY_PN}
+}
+
+src_prepare() {
+ default
+
+ # remove bundled nodejs
+ rm -r node || die
+
+ # remove empty unused directory
+ rmdir data || die
+
+ # handle node.js version with RDEPEND
+ sed -i /node_version_validator/d src/setup_node_env/index.js || die
+}
+
+src_install() {
+ insinto /etc/${MY_PN}
+ doins -r config/.
+ rm -r config || die
+
+ insinto /etc/logrotate.d
+ newins "${FILESDIR}"/${MY_PN}.logrotate ${MY_PN}
+
+ newconfd "${FILESDIR}"/${MY_PN}.confd ${MY_PN}
+ newinitd "${FILESDIR}"/${MY_PN}.initd ${MY_PN}
+ systemd_dounit "${FILESDIR}"/${MY_PN}.service
+
+ insinto /opt/${MY_PN}
+ doins -r .
+
+ fperms -R +x /opt/${MY_PN}/bin
+
+ diropts -m 0750 -o ${MY_PN} -g ${MY_PN}
+ keepdir /var/log/${MY_PN}
+}
+
+pkg_postinst() {
+ elog "This version of Kibana is compatible with Elasticsearch $(ver_cut 1-2) and"
+ elog "Node.js 8. Some plugins may fail with other versions of Node.js (Bug #656008)."
+ elog
+ elog "To set a customized Elasticsearch instance:"
+ elog " OpenRC: set ES_INSTANCE in /etc/conf.d/${MY_PN}"
+ elog " systemd: set elasticsearch.url in /etc/${MY_PN}/kibana.yml"
+ elog
+ elog "Elasticsearch can run local or remote."
+}