www-client/opera-beta: automated bump (86.0.4363.12)

Signed-off-by: Stephan Hartmann <sultan@gentoo.org>

2 files changed, 159 insertions, 0 deletions

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index 3ff86d39f0c2..5f863821657d 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,5 +1,6 @@
 DIST opera-beta_85.0.4341.10_amd64.deb 84667120 BLAKE2B b06310d411dd1789a22a1dda14001786c73c3b7f83fad5358f6193b19e66ad656cf237ba8ed17cf565eb4880f45342f79573353f321ebc0fa4e2db597f408255 SHA512 efb44e1a710536dc626e4d963d614bc114acedc24e56f00513996771d27989d5cb04de822760bb9152ce451b59010a9583f06c40fe077f58aa491222afe6b6f0
 DIST opera-beta_85.0.4341.13_amd64.deb 84607344 BLAKE2B f17906444e77670131c00fb3ce490dfd3a59d6bb99bef01c0d02934cbe2bf852f374d20e1a5ec5754b1179727cc32bc5a04315c2b0acba3a1cab12594aa1baef SHA512 a2a51dbeb20791709bb3bf94e717a083a0dfc7d0d743180ee79eed934179c9bd35063ff123ac74fcbdbc5d373e71b7ea054437866dfcc4ffcee5812e4542c315
+DIST opera-beta_86.0.4363.12_amd64.deb 84459428 BLAKE2B 3ae8e8ee977143df6dea0f42f2bb8ae840175306fb6db632406e227d3cb895c5f7b845495c95f449d0d6697976c2b50904b9cda1c7f4fa0eea95af95a320bde4 SHA512 49a6240e2a6ee3bcd1effbb5518859209e92864e800b25b247892579dd0891a9cb8f81b32fbce3c229d7529f429ee65c2a1d44cccbe702f2d2325e5a50fbb396
 DIST opera-beta_86.0.4363.9_amd64.deb 84476288 BLAKE2B 7f7a33145264b86c9ada334f497a2f0ce7d3ad931d4653d1f3d66e863913c77150e16d578865da64708f424c41ce8a669dcae5a954dd2489e80e9c014bfa4d8a SHA512 e5bb6093a864e58f204b0fde5bc962b6b3cdab6da7efb081d497129abc9e0e6bf02684e220377a2248321ee5050aae665f25299881734313e7e038cec4b6c239
 DIST opera-ffmpeg-codecs-100.0.4896.20.tar.xz 1393360 BLAKE2B be608a42042b2713fff66716c171959609e06d94b6c56cd8081e05313915378eff25c7098228ff6727a430c9f02bd4e9c9dcce4e715f09e10ac62d89ccd6ae1c SHA512 7dab4a091ac3562cd9c09cf37bc70edf9000ad1b3d31f27278e2edc68b9f55fd4f821ebc90a761ae5803542195718015c859e107344b31a5f7f9ad6cf028df42
 DIST opera-ffmpeg-codecs-99.0.4818.2.tar.xz 1394204 BLAKE2B b18569d0adef52d88f0c39391da330e3df5fae1fa323dcda82d6d432c5e8bc9c24008cbff61eeded6a61255ef0fabf4a1cef554b3acad42c500cbfde89c254dc SHA512 8ab7836c663a540e34a92f7a38571b968bf23fd44af554ee8ba3b7affb991031bf9aba2a848e68e478e7431efccf4410c7398bacee831f1b16be91dd65b151bb
diff --git a/www-client/opera-beta/opera-beta-86.0.4363.12.ebuild b/www-client/opera-beta/opera-beta-86.0.4363.12.ebuild
new file mode 100644
index 000000000000..d1fbcd0074a1
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-86.0.4363.12.ebuild
@@ -0,0 +1,158 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="100.0.4896.20"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}