www-servers/gunicorn: Version Bump

Package-Manager: portage-2.2.20
Signed-off-by: Justin Lecher <jlec@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/www-servers/gunicorn/gunicorn-19.3.0.ebuild b/www-servers/gunicorn/gunicorn-19.3.0.ebuild
new file mode 100644
index 000000000000..d50ed822d766
--- /dev/null
+++ b/www-servers/gunicorn/gunicorn-19.3.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="A WSGI HTTP Server for UNIX"
+HOMEPAGE="http://gunicorn.org http://pypi.python.org/pypi/gunicorn https://github.com/benoitc/gunicorn"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND="dev-python/setproctitle[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)"
+
+DOCS="README.rst"
+
+python_prepare_all() {
+	# these tests requires an already installed version of gunicorn
+	rm tests/test_003-config.py || die
+
+	sed -ie "s/..\/bin/\/usr\/bin\//" docs/Makefile || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test -v || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	use examples && EXAMPLES=( examples/. )
+
+	distutils-r1_python_install_all
+}