x11-apps/igt-gpu-tools: fix compat w/ procps-4

Closes: https://bugs.gentoo.org/913512
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 113 insertions, 0 deletions

diff --git a/x11-apps/igt-gpu-tools/Manifest b/x11-apps/igt-gpu-tools/Manifest
index 20bbf7eaf35c..00aa0f839161 100644
--- a/x11-apps/igt-gpu-tools/Manifest
+++ b/x11-apps/igt-gpu-tools/Manifest
@@ -1 +1,2 @@
+DIST igt-gpu-tools-1.27.1-patches.tar.xz 5608 BLAKE2B 01c3cd14a7e920930dea96de6136c3b0236204998d9ad39775f6f9d6e1eb248bfb67651cabc23d50ec88b052c4e35194da2fe0ac05fe7084b771892cd9e2f328 SHA512 ef00c789374bd3a2961d6d989f557026f68f94e929c74ffb1c078c6106c734960f40442cae5d3b7b2b5fef99f8ffdaccb2ef8bdb5d93fe430cc0038e5f32baa8
 DIST igt-gpu-tools-1.27.1.tar.xz 2321940 BLAKE2B b6c4fee31c97cd5005c1f2cd5c18c181582adfb27e92444a8e78d1c105acb78a424bd4e4af8d13333776c81531fbfd24dc4b7db0da9858f5b803f64962d6269d SHA512 20923505e9afe6e5064bf8f4056e027ff0321cd29d8982157a608369aea6fbef24c93756de96ef6296e09d539957fc6cdad4097cbab5af33f8828f762da0d8c0
diff --git a/x11-apps/igt-gpu-tools/igt-gpu-tools-1.27.1-r1.ebuild b/x11-apps/igt-gpu-tools/igt-gpu-tools-1.27.1-r1.ebuild
new file mode 100644
index 000000000000..58906196dc9a
--- /dev/null
+++ b/x11-apps/igt-gpu-tools/igt-gpu-tools-1.27.1-r1.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+EGIT_REPO_URI="https://gitlab.freedesktop.org/drm/${PN}.git"
+if [[ ${PV} = *9999* ]]; then
+	GIT_ECLASS="git-r3"
+fi
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit ${GIT_ECLASS} meson python-any-r1
+
+DESCRIPTION="Intel GPU userland tools"
+
+HOMEPAGE="https://gitlab.freedesktop.org/drm/igt-gpu-tools"
+if [[ ${PV} = *9999* ]]; then
+	SRC_URI=""
+else
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://www.x.org/releases/individual/app/${P}.tar.xz"
+	# Only needed for 1.27.1, fixed in git, just for procps-4 support
+	SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-patches.tar.xz"
+fi
+LICENSE="MIT"
+SLOT="0"
+IUSE="chamelium doc man overlay runner tests unwind valgrind video_cards_amdgpu video_cards_intel video_cards_nouveau X xv"
+REQUIRED_USE="
+	|| ( video_cards_amdgpu video_cards_intel video_cards_nouveau )
+	overlay? (
+		video_cards_intel
+		|| ( X xv )
+	)
+	doc? ( tests )
+	runner? ( tests )
+"
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/elfutils
+	dev-libs/glib:2
+	sys-apps/kmod:=
+	sys-libs/zlib:=
+	sys-process/procps:=
+	virtual/libudev:=
+	>=x11-libs/cairo-1.12.0[X?]
+	>=x11-libs/libdrm-2.4.82[video_cards_amdgpu?,video_cards_intel?,video_cards_nouveau?]
+	>=x11-libs/libpciaccess-0.10
+	x11-libs/pixman
+	chamelium? (
+		dev-libs/xmlrpc-c:=[curl]
+		sci-libs/gsl:=
+		media-libs/alsa-lib:=
+	)
+	overlay? (
+		>=x11-libs/libXrandr-1.3
+		xv? (
+			x11-libs/libX11
+			x11-libs/libXext
+			x11-libs/libXv
+		)
+	)
+	runner? ( dev-libs/json-c:= )
+	unwind? ( sys-libs/libunwind:= )
+	valgrind? ( dev-util/valgrind )
+	"
+DEPEND="${RDEPEND}
+	doc? ( >=dev-util/gtk-doc-1.25-r1 )
+	man? ( dev-python/docutils )
+	overlay? (
+		>=dev-util/peg-0.1.18
+		x11-base/xorg-proto
+	)
+	video_cards_intel? (
+		sys-devel/bison
+		sys-devel/flex
+	)
+"
+BDEPEND="${PYTHON_DEPS}"
+
+PATCHES=(
+	"${WORKDIR}"/${P}-patches
+)
+
+src_prepare() {
+	sed -e "s/find_program('rst2man-3'/find_program('rst2man.py', 'rst2man-3'/" -i man/meson.build
+	default_src_prepare
+}
+
+src_configure() {
+	local gpus=""
+	use video_cards_amdgpu  && gpus+="amdgpu,"
+	use video_cards_intel   && gpus+="intel,"
+	use video_cards_nouveau && gpus+="nouveau,"
+
+	local overlay_backends=""
+	use overlay && use xv && overlay_backends+="xv,"
+	use overlay && use X && overlay_backends+="x,"
+
+	local emesonargs=(
+		$(meson_feature chamelium)
+		$(meson_feature doc docs)
+		$(meson_feature man)
+		$(meson_feature overlay)
+		$(meson_feature runner)
+		$(meson_feature tests)
+		$(meson_feature valgrind)
+		$(meson_feature unwind libunwind)
+		-Doverlay_backends=${overlay_backends%?}
+		-Dlibdrm_drivers=${gpus%?}
+	)
+	meson_src_configure
+}