x11-libs/vte: Version bump to 0.62.3

Signed-off-by: Matt Turner <mattst88@gentoo.org>

1 files changed, 80 insertions, 0 deletions

diff --git a/x11-libs/vte/vte-0.62.3.ebuild b/x11-libs/vte/vte-0.62.3.ebuild
new file mode 100644
index 000000000000..80301a89aacd
--- /dev/null
+++ b/x11-libs/vte/vte-0.62.3.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+VALA_MIN_API_VERSION="0.32"
+
+inherit gnome.org meson vala xdg
+
+DESCRIPTION="Library providing a virtual terminal emulator widget"
+HOMEPAGE="https://wiki.gnome.org/Apps/Terminal/VTE"
+
+LICENSE="LGPL-3+ GPL-3+"
+SLOT="2.91"
+IUSE="+crypt debug gtk-doc +icu +introspection systemd +vala vanilla"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
+REQUIRED_USE="vala? ( introspection )"
+
+SRC_URI="${SRC_URI} !vanilla? ( https://dev.gentoo.org/~mattst88/distfiles/${PN}-0.62.1-command-notify.patch.xz )"
+
+RDEPEND="
+	>=x11-libs/gtk+-3.24.14:3[introspection?]
+	>=dev-libs/fribidi-1.0.0
+	>=dev-libs/glib-2.52:2
+	crypt?  ( >=net-libs/gnutls-3.2.7:0= )
+	icu? ( dev-libs/icu:= )
+	>=x11-libs/pango-1.22.0
+	>=dev-libs/libpcre2-10.21
+	systemd? ( >=sys-apps/systemd-220:= )
+	sys-libs/zlib
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+	x11-libs/pango[introspection?]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.13
+		app-text/docbook-xml-dtd:4.1.2 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	if ! use vanilla; then
+		# Part of https://src.fedoraproject.org/rpms/vte291/raw/f31/f/vte291-cntnr-precmd-preexec-scroll.patch
+		# Adds OSC 777 support for desktop notifications in gnome-terminal or elsewhere
+		eapply "${WORKDIR}"/${PN}-0.62.1-command-notify.patch
+	fi
+
+	# -Ddebugg option enables various debug support via VTE_DEBUG, but also ggdb3; strip the latter
+	sed -e '/ggdb3/d' -i meson.build || die
+
+	use vala && vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Da11y=true
+		$(meson_use debug debugg)
+		$(meson_use gtk-doc docs)
+		$(meson_use introspection gir)
+		-Dfribidi=true # pulled in by pango anyhow
+		$(meson_use crypt gnutls)
+		-Dgtk3=true
+		-Dgtk4=false
+		$(meson_use icu)
+		$(meson_use systemd _systemd)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	mv "${ED}"/etc/profile.d/vte{,-${SLOT}}.sh || die
+}