proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 100 insertions, 0 deletions

diff --git a/x11-misc/xaos/xaos-3.6.ebuild b/x11-misc/xaos/xaos-3.6.ebuild
new file mode 100644
index 000000000000..58546a88900f
--- /dev/null
+++ b/x11-misc/xaos/xaos-3.6.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=1
+AUTOTOOLS_IN_SOURCE_BUILD=1
+
+inherit autotools-utils eutils
+
+DESCRIPTION="Very fast real-time fractal zoomer"
+HOMEPAGE="http://matek.hu/xaos/doku.php"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+	http://dev.gentoo.org/~jlec/distfiles/${PN}.png.tar"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="aalib doc -gtk nls png svga threads X"
+
+RDEPEND="
+	sci-libs/gsl:0=
+	sys-libs/zlib:0=
+	aalib? ( media-libs/aalib:0= )
+	gtk? ( x11-libs/gtk+:2= )
+	nls? ( sys-devel/gettext )
+	png? ( media-libs/libpng:0= )
+	X? ( x11-libs/libX11:0=
+		 x11-libs/libXext:0=
+		 x11-libs/libXxf86vm:0= )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( virtual/texi2dvi )
+	X? (
+		x11-proto/xf86vidmodeproto
+		x11-proto/xextproto
+		x11-proto/xproto )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.4-png.patch
+	"${FILESDIR}"/${PN}-3.4-include.patch
+	"${FILESDIR}"/${PN}-3.5-build-fix-i686.patch
+	"${FILESDIR}"/${PN}-3.6-locale-dir.patch
+	"${FILESDIR}"/${PN}-3.6-no-auto-strip.patch
+)
+
+src_prepare() {
+	autotools-utils_src_prepare
+	if use nls; then
+		if [[ "${LINGUAS+set}" == "set" ]]; then
+			strip-linguas -i src/i18n
+			sed -i -e '/^ALL_LINGUAS=/d' configure || die
+			export ALL_LINGUAS="${LINGUAS}"
+		fi
+	else
+		sed -i -e '/^ALL_LINGUAS=/d' configure || die
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-sffe=yes
+		--with-gsl=yes
+		$(use_enable nls)
+		$(use_with png)
+		$(use_with aalib aa-driver)
+		$(use_with gtk gtk-driver)
+		$(use_with threads pthread)
+		$(use_with X x11-driver)
+		$(use_with X x)
+	)
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	autotools-utils_src_compile
+	if use doc; then
+		cd "${BUILD_DIR}"/doc
+		emake xaos.dvi
+		dvipdf xaos.dvi || die
+		cd "${BUILD_DIR}"/help
+		emake html
+	fi
+}
+
+src_install() {
+	autotools-utils_src_install
+	if use doc; then
+		insinto /usr/share/doc/${PF}
+		doins doc/xaos.pdf
+		dohtml -r help/*
+	fi
+	local driver="x11"
+	use gtk && driver="\"GTK+ Driver\""
+	make_desktop_entry "xaos -driver ${driver}" "XaoS Fractal Zoomer" \
+		xaos "Application;Education;Math;Graphics;"
+	doicon "${WORKDIR}"/${PN}.png
+}