x11-misc/gammastep: New package, fork of x11-misc/redshift

Bug: https://bugs.gentoo.org/887979
Signed-off-by: Sebastian Pipping <sping@gentoo.org>

3 files changed, 99 insertions, 0 deletions

diff --git a/x11-misc/gammastep/Manifest b/x11-misc/gammastep/Manifest
new file mode 100644
index 000000000000..8271eaf5c96d
--- /dev/null
+++ b/x11-misc/gammastep/Manifest
@@ -0,0 +1 @@
+DIST gammastep-v2.0.9.tar.bz2 540120 BLAKE2B cfc29b157ad2dbd3d6bb0ac4bdb26c958ba07cad3e817931c2ee4c2e4d15c157b7c0b8b891869ddcc2cdfc39c1d52afb8437991ae60501afee84500e1f28c694 SHA512 d8b23e5890d6135cef79057408e1b7c1dbc36444dfbfaf7c80a3f36c46df19eaded1829c2cd52365413779cc752d0911a44669b5abce16d7e266b92b15c035fb
diff --git a/x11-misc/gammastep/gammastep-2.0.9.ebuild b/x11-misc/gammastep/gammastep-2.0.9.ebuild
new file mode 100644
index 000000000000..f7682fb8928a
--- /dev/null
+++ b/x11-misc/gammastep/gammastep-2.0.9.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit autotools systemd xdg-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="https://gitlab.com/chinstrap/gammastep"
+SRC_URI="https://gitlab.com/chinstrap/gammastep/-/archive/v${PV}/gammastep-v${PV}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="appindicator geoclue gtk nls wayland"
+
+COMMON_DEPEND=">=x11-libs/libX11-1.4
+	x11-libs/libXxf86vm
+	x11-libs/libxcb
+	x11-libs/libdrm
+	appindicator? ( dev-libs/libappindicator:3[introspection] )
+	geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
+	gtk? ( ${PYTHON_DEPS} )"
+RDEPEND="${COMMON_DEPEND}
+	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+		dev-python/pyxdg[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	nls? ( sys-devel/gettext )
+"
+REQUIRED_USE="gtk? ( ${PYTHON_REQUIRED_USE} )"
+
+S="${WORKDIR}"/${PN}-v${PV}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use gtk && python_setup
+
+	econf \
+		$(use_enable nls) \
+		--enable-drm \
+		$(use_enable wayland) \
+		--enable-randr \
+		--enable-vidmode \
+		$(use_enable geoclue geoclue2) \
+		$(use_enable gtk gui) \
+		--enable-apparmor \
+		--with-systemduserunitdir="$(systemd_get_userunitdir)"
+}
+
+_impl_specific_src_install() {
+	emake DESTDIR="${D}" \
+		PYTHON="${PYTHON}" \
+		pythondir="$(python_get_sitedir)" \
+		-C src/gammastep_indicator install
+}
+
+src_install() {
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install
+
+	if use gtk; then
+		python_foreach_impl _impl_specific_src_install
+		python_replicate_script "${D}"/usr/bin/gammastep-indicator
+
+		python_foreach_impl python_optimize
+	fi
+
+	insinto /etc/gammastep/
+	newins gammastep.conf.sample config.ini.example
+}
+
+pkg_postinst() {
+	use gtk && xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && xdg_icon_cache_update
+}
diff --git a/x11-misc/gammastep/metadata.xml b/x11-misc/gammastep/metadata.xml
new file mode 100644
index 000000000000..e737ed459914
--- /dev/null
+++ b/x11-misc/gammastep/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>sping@gentoo.org</email>
+  </maintainer>
+  <use>
+    <flag name="geoclue">Control dependency on <pkg>app-misc/geoclue</pkg></flag>
+  </use>
+  <upstream>
+    <remote-id type="gitlab">chinstrap/gammastep</remote-id>
+  </upstream>
+</pkgmetadata>