x11-terms/sakura: Fix tab closing segmentation fault

Fixes: https://bugs.gentoo.org/670216
Package-Manager: Portage-2.3.51, Repoman-2.3.11
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

1 files changed, 67 insertions, 0 deletions

diff --git a/x11-terms/sakura/sakura-3.6.0-r1.ebuild b/x11-terms/sakura/sakura-3.6.0-r1.ebuild
new file mode 100644
index 000000000000..9f68fad99741
--- /dev/null
+++ b/x11-terms/sakura/sakura-3.6.0-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils eutils flag-o-matic gnome2-utils xdg-utils
+
+DESCRIPTION="sakura is a terminal emulator based on GTK and VTE"
+HOMEPAGE="http://www.pleyades.net/david/projects/sakura/"
+SRC_URI="https://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-linux"
+
+RDEPEND="
+	>=dev-libs/glib-2.20:2
+	x11-libs/gtk+:3[X]
+	x11-libs/libX11
+	>x11-libs/vte-0.50:2.91
+"
+DEPEND="
+	${RDEPEND}
+	>=dev-lang/perl-5.10.1
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.1.3-flags.patch
+	"${FILESDIR}"/${PN}-3.6.0-tab-crash.patch
+)
+
+DOCS=(
+	AUTHORS
+)
+
+src_prepare() {
+	sed -i "/FILES INSTALL/d" CMakeLists.txt || die
+
+	strip-linguas -i po/
+	local lingua
+	for lingua in po/*.po; do
+		lingua="${lingua/po\/}"
+		lingua="${lingua/.po}"
+		if ! has ${lingua} ${LINGUAS}; then
+			rm po/${lingua}.po || die
+		fi
+	done
+
+	cmake-utils_src_prepare
+	# sakura.c:1740:3: warning: implicit declaration of function ‘readlink’
+	# [-Wimplicit-function-declaration]
+	append-cppflags -D_DEFAULT_SOURCE
+
+	# sakura.c:1348:9: error: ‘for’ loop initial declarations are only allowed
+	# in C99 or C11 mode
+	append-cflags -std=c99
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}