x11-themes/tela-icon-theme: add 20220828

Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/x11-themes/tela-icon-theme/Manifest b/x11-themes/tela-icon-theme/Manifest
index f7ef1cd16046..d81849bc7e86 100644
--- a/x11-themes/tela-icon-theme/Manifest
+++ b/x11-themes/tela-icon-theme/Manifest
@@ -1 +1,2 @@
 DIST tela-icon-theme-20211225.tar.gz 3592063 BLAKE2B d5b16f4f3899fc162082d2ee2432367e4b81527e71d1689c1f9f930bb22a799485d3b127f9aafa803b3356ad462e59cd5e78ae17fdd7607edf68794307c0c8d8 SHA512 4b4db7c07e4349879dd6568b0cd06476027cef173565bb91fe89909cf1d6bbad591c6b9ce29c81bef03f71211fc06d71da353e9116103b8407b0fb3141e0d949
+DIST tela-icon-theme-20220828.tar.gz 3707567 BLAKE2B 61a72b96df08cb5f3ef80b7aea5ca05e9b142607672f7213494c6f9fd0f458eeb87bd80842e14b7ed260f533088711f433357179c7c53d5beeeb76bafe2817d5 SHA512 6f0d26678ead12043bfc8943e2d40a507c2cfa8136a1556d53444efa5b1f6903307aead9255a38b3411980bd5353c3497bf224c1ed66a620d229b6a9a9079f83
diff --git a/x11-themes/tela-icon-theme/tela-icon-theme-20220828.ebuild b/x11-themes/tela-icon-theme/tela-icon-theme-20220828.ebuild
new file mode 100644
index 000000000000..8396dac63033
--- /dev/null
+++ b/x11-themes/tela-icon-theme/tela-icon-theme-20220828.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# eg. 20211225 -> 2021-12-25
+MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
+MY_PN="${PN^}"
+
+# standard comes first
+MY_COLOR_VARIANTS=( standard black blue brown green grey orange pink purple red yellow manjaro ubuntu )
+
+inherit xdg
+
+DESCRIPTION="A flat colorful Design icon theme"
+HOMEPAGE="https://github.com/vinceliuice/Tela-icon-theme"
+
+if [[ ${PV} == 99999999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/vinceliuice/${MY_PN}.git"
+else
+	SRC_URI="https://github.com/vinceliuice/${MY_PN}/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64"
+	S="${WORKDIR}/${MY_PN}-${MY_PV}"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+${MY_COLOR_VARIANTS[*]} +hardlink kde" # this is why standard comes first
+
+REQUIRED_USE="|| ( ${MY_COLOR_VARIANTS[*]} )"
+
+# not needed and slows us down, package installs 120 000 small files
+RESTRICT="binchecks strip test"
+
+# technically we can use app-arch/harlink too, but it's deprecated
+BDEPEND="
+	app-shells/bash
+	sys-apps/util-linux[hardlink(-)?]
+"
+
+src_prepare() {
+	default
+	# we use eclass for that
+	sed -i '/gtk-update-icon-cache/d' install.sh || die
+}
+
+src_install() {
+	local v variants=(
+		$(usev kde '-c')
+		$(for v in ${MY_COLOR_VARIANTS[@]}; do
+			usev ${v}
+		done)
+	)
+
+	dodir /usr/share/icons
+	./install.sh -d "${ED}/usr/share/icons" "${variants[@]}" || die
+	if use hardlink; then
+		einfo "Linking duplicate icons... (may take a long time)"
+		hardlink -pot "${ED}/usr/share/icons" || die "hardlink failed"
+	fi
+
+	# installs broken symlink (by design, but we remove it due to QA warnings)
+	# https://bugs.gentoo.org/830467
+	find "${ED}" -xtype l -name uav.svg -delete || die "removing broken symlinks failed"
+
+	einstalldocs
+}