x11-wm/emerald: revision bump

Bump EAPI to 6, fix crash in cairo processing with some UTF-8 symbols
in windows title - backported from compiz-reloaded project.
Drop old revision

Package-Manager: portage-2.2.28

1 files changed, 59 insertions, 0 deletions

diff --git a/x11-wm/emerald/emerald-0.8.8-r1.ebuild b/x11-wm/emerald/emerald-0.8.8-r1.ebuild
new file mode 100644
index 000000000000..be388ba89b8a
--- /dev/null
+++ b/x11-wm/emerald/emerald-0.8.8-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit eutils flag-o-matic
+
+THEMES_RELEASE=0.5.2
+
+DESCRIPTION="Emerald Window Decorator"
+HOMEPAGE="http://www.compiz.org/"
+SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+PDEPEND="~x11-themes/emerald-themes-${THEMES_RELEASE}"
+
+RDEPEND="
+	>=x11-libs/gtk+-2.8.0:2
+	>=x11-libs/libwnck-2.14.2:1
+	>=x11-wm/compiz-${PV}
+"
+
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
+	virtual/pkgconfig
+	>=sys-devel/gettext-0.15
+"
+
+DOCS=( AUTHORS ChangeLog INSTALL NEWS README TODO )
+
+src_prepare() {
+	# Fix pkg-config file pollution wrt #380197
+	eapply "${FILESDIR}/${P}-pkgconfig-pollution.patch"
+	# Fix crashes with some UTF-8 characters in window title
+	eapply "${FILESDIR}/${P}-fix-cairo-crash.patch"
+	# fix build with gtk+-2.22 - bug 341143
+	sed -i -e '/#define G[DT]K_DISABLE_DEPRECATED/s:^://:' \
+		include/emerald.h || die
+	# Fix underlinking
+	append-libs -ldl -lm
+
+	eapply_user
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--enable-fast-install \
+		--disable-mime-update
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}