3 files changed, 154 insertions, 0 deletions
diff --git a/dev-lua/luaexpat/luaexpat-1.3.0-r102.ebuild b/dev-lua/luaexpat/luaexpat-1.3.0-r102.ebuild
new file mode 100644
index 000000000000..ce6096ca0c47
--- /dev/null
+++ b/dev-lua/luaexpat/luaexpat-1.3.0-r102.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="LuaExpat is a SAX XML parser based on the Expat library"
+HOMEPAGE="https://matthewwild.co.uk/projects/luaexpat/"
+SRC_URI="https://matthewwild.co.uk/projects/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	dev-libs/expat
+	${LUA_DEPS}
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+HTML_DOCS=( "doc/us/." )
+
+src_prepare() {
+	default
+
+	# Respect users CFLAGS
+	# Add '-DLUA_32BITS' for fixing compilation with lua5.3
+	sed -e 's/-O2/-DLUA_32BITS/g' -i Makefile || die
+
+	lua_copy_sources
+}
+
+lua_src_compile() {
+	pushd "${BUILD_DIR}" || die
+
+	local myemakeargs=(
+		"CC=$(tc-getCC)"
+		"LUA_INC=$(lua_get_CFLAGS)"
+	)
+
+	emake "${myemakeargs[@]}"
+
+	popd
+}
+
+src_compile() {
+	lua_foreach_impl lua_src_compile
+}
+
+lua_src_install() {
+	pushd "${BUILD_DIR}" || die
+
+	local myemakeargs=(
+		"DESTDIR=${ED}"
+		"LUA_CDIR=$(lua_get_cmod_dir)"
+		"LUA_INC=$(lua_get_include_dir)"
+		"LUA_LDIR=$(lua_get_lmod_dir)"
+	)
+
+	emake "${myemakeargs[@]}" install
+
+	popd
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+
+	einstalldocs
+}
diff --git a/dev-lua/luaexpat/luaexpat-1.3.3-r102.ebuild b/dev-lua/luaexpat/luaexpat-1.3.3-r102.ebuild
new file mode 100644
index 000000000000..e1907b637e49
--- /dev/null
+++ b/dev-lua/luaexpat/luaexpat-1.3.3-r102.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="LuaExpat is a SAX XML parser based on the Expat library"
+HOMEPAGE="https://github.com/tomasguisasola/luaexpat"
+SRC_URI="https://github.com/tomasguisasola/luaexpat/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	dev-libs/expat
+	${LUA_DEPS}
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+HTML_DOCS=( "doc/us/." )
+
+PATCHES=(
+	"${FILESDIR}/${P}_makefile.patch"
+	"${FILESDIR}/${P}_getcurrentbytecount.patch"
+	"${FILESDIR}/${P}_restore_functionality.patch"
+)
+
+src_prepare() {
+	default
+
+	# Respect users CFLAGS
+	sed -e 's/-O2//g' -i makefile || die
+
+	lua_copy_sources
+}
+
+lua_src_compile() {
+	pushd "${BUILD_DIR}" || die
+
+	local myemakeargs=(
+		"CC=$(tc-getCC) ${CFLAGS}"
+		"LUA_INC=$(lua_get_include_dir)"
+	)
+
+	emake "${myemakeargs[@]}"
+
+	popd
+}
+
+src_compile() {
+	lua_foreach_impl lua_src_compile
+}
+
+lua_src_install() {
+	pushd "${BUILD_DIR}" || die
+
+	local myemakeargs=(
+		"LUA_DIR=${ED}/$(lua_get_lmod_dir)"
+		"LUA_INC=${ED}/$(lua_get_include_dir)"
+		"LUA_LIBDIR=${ED}/$(lua_get_cmod_dir)"
+	)
+
+	emake "${myemakeargs[@]}" install
+
+	popd
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+
+	einstalldocs
+}
diff --git a/profiles/package.mask b/profiles/package.mask
index 8bfea7d46006..e1eae295d77b 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -542,7 +542,9 @@ kde-apps/kdebase-meta:5
 >=dev-lua/luadbi-0.7.2-r100
 >=dev-lua/luaevent-0.4.6-r100
 =dev-lua/luaexpat-1.3.0-r101
+=dev-lua/luaexpat-1.3.0-r102
 =dev-lua/luaexpat-1.3.3-r101
+=dev-lua/luaexpat-1.3.3-r102
 >=dev-lua/luafilesystem-1.8.0-r100
 >=dev-lua/lualdap-1.2.5-r100
 >=dev-lua/luajson-1.3.4-r100