4 files changed, 102 insertions, 0 deletions
diff --git a/sys-apps/intune-portal/Manifest b/sys-apps/intune-portal/Manifest
new file mode 100644
index 000000000000..0c2a5f762d54
--- /dev/null
+++ b/sys-apps/intune-portal/Manifest
@@ -0,0 +1 @@
+DIST intune-portal_1.2402.12-jammy_amd64.deb 6638942 BLAKE2B 2421961fb3df92aa3aaf36b4d49b1a77d895dd184bc09d8fd53f528f20791070d87f31bfa9c3cc4c205fabc8c8e3d0309fc15d2a763f75307fa4be94e277b11d SHA512 7730896d1c2a47354e3cb2aa881de3fab086415606fe0b09506c016db6bd1acd8d86c9be24984ccdb921b59fe1a6eb99bfd5c5087a7602deb1e2afb29ead3d44
diff --git a/sys-apps/intune-portal/files/wrapper b/sys-apps/intune-portal/files/wrapper
new file mode 100644
index 000000000000..33bcc59f8344
--- /dev/null
+++ b/sys-apps/intune-portal/files/wrapper
@@ -0,0 +1,10 @@
+#!/bin/sh
+
+exec bwrap \
+    --bind / / \
+    --dev-bind /dev /dev \
+    --ro-bind /etc/microsoft-identity-broker/lsb-release /etc/lsb-release \
+    --ro-bind /etc/microsoft-identity-broker/os-release /etc/os-release \
+    --ro-bind /etc/pam.d/system-auth /etc/pam.d/common-password \
+    -- \
+    /opt/microsoft/intune/libexec/"${0##*/}" "${@}"
diff --git a/sys-apps/intune-portal/intune-portal-1.2402.12.ebuild b/sys-apps/intune-portal/intune-portal-1.2402.12.ebuild
new file mode 100644
index 000000000000..47eb619b6b16
--- /dev/null
+++ b/sys-apps/intune-portal/intune-portal-1.2402.12.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop pam prefix systemd tmpfiles unpacker xdg
+
+DESCRIPTION="Microsoft Intune Company Portal to access a corporate environment"
+HOMEPAGE="https://learn.microsoft.com/mem/intune/"
+SRC_URI="https://packages.microsoft.com/ubuntu/22.04/prod/pool/main/${PN:0:1}/${PN}/${PN}_${PV}-jammy_amd64.deb"
+S="${WORKDIR}"
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+RESTRICT="bindist mirror"
+
+RDEPEND="
+	app-accessibility/at-spi2-core:2
+	app-crypt/libsecret
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/openssl:0/3
+	net-libs/libsoup:2.4
+	net-libs/webkit-gtk:4/37
+	net-misc/curl
+	sys-apps/bubblewrap
+	sys-apps/dbus
+	sys-apps/lsb-release
+	sys-apps/systemd
+	sys-apps/util-linux
+	sys-auth/microsoft-identity-broker
+	sys-auth/pambase[pwquality]
+	sys-auth/polkit
+	sys-libs/pam
+	sys-libs/zlib
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/pango
+
+	|| (
+		www-client/microsoft-edge
+		www-client/microsoft-edge-beta
+		www-client/microsoft-edge-dev
+	)
+"
+
+QA_PREBUILT="*"
+DIR="/opt/microsoft/intune"
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+src_install() {
+	exeinto "${DIR}"/bin
+	newexe $(prefixify_ro "${FILESDIR}"/wrapper) intune-portal
+	dosym intune-portal /opt/microsoft/intune/bin/intune-agent
+	dosym intune-portal /opt/microsoft/intune/bin/intune-daemon
+
+	exeinto "${DIR}"/libexec
+	doexe "${DIR#/}"/bin/*
+
+	insinto "${DIR}"/share
+	doins -r "${DIR#/}"/share/*
+
+	insinto /usr/share/polkit-1/actions
+	doins usr/share/polkit-1/actions/com.microsoft.intune.policy
+
+	systemd_dounit lib/systemd/system/*
+	systemd_douserunit lib/systemd/user/*
+
+	dopammod usr/lib/x86_64-linux-gnu/security/pam_intune.so
+	dotmpfiles usr/lib/tmpfiles.d/intune.conf
+
+	domenu usr/share/applications/*.desktop
+	doicon -s 48 usr/share/icons/hicolor/48x48/*/*.png
+}
+
+pkg_postinst() {
+	touch "${EROOT}"/etc/pam.d/common-password || die
+	tmpfiles_process intune.conf
+	xdg_pkg_postinst
+}
diff --git a/sys-apps/intune-portal/metadata.xml b/sys-apps/intune-portal/metadata.xml
new file mode 100644
index 000000000000..374cd4dedb33
--- /dev/null
+++ b/sys-apps/intune-portal/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>chewi@gentoo.org</email>
+		<name>James Le Cuirot</name>
+	</maintainer>
+</pkgmetadata>