7 files changed, 254 insertions, 118 deletions

diff --git a/app-arch/dump/Manifest b/app-arch/dump/Manifest
index 02c875b0defc..09804a91cee3 100644
--- a/app-arch/dump/Manifest
+++ b/app-arch/dump/Manifest
@@ -1 +1 @@
-DIST dump-0.4b46.tar.gz 578200 BLAKE2B 91102bdba06f3affdf4ebd9de525145c0a4cc1b9fb4c6ff222c411c118b3b7835f3aad666d530019d8b9ee46590e4a283a143d188d6800218100cecf67877274 SHA512 a30e72ab6c4d18497dffe3d25634c2e55ca90861d1cd8a6c0fd44709e735a217dbf4cdabb8c80e02053def94d9a22cf1d685ee0d0f24f5b748ee5f0de19cf17d
+DIST dump-0.4b47.tar.gz 583380 BLAKE2B a5a6c507fc67451e6ce5117b28b9e97e45783059358c357e1f6d4b268437c8340f13e0d77e97631112824eca8205c49d206a8a7904bc3e00b1f0d5abb31418f7 SHA512 e9c567fe2ffad196b9657c551d83f7607758f3704cad6cb407514bbe2bc765c16968997dc3a5bc92b9eb5900fa5bd6e7cebc92c81afff53339fca92891a5259d
diff --git a/app-arch/dump/dump-0.4.46-r1.ebuild b/app-arch/dump/dump-0.4.47-r1.ebuild
index c768fa8534d8..c3d4771f7b31 100644
--- a/app-arch/dump/dump-0.4.46-r1.ebuild
+++ b/app-arch/dump/dump-0.4.47-r1.ebuild
@@ -1,42 +1,42 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
 MY_P="${PN}-$(ver_rs 2 b)"
-S=${WORKDIR}/${MY_P}
+
 DESCRIPTION="Dump/restore ext2fs backup utilities"
 HOMEPAGE="http://dump.sourceforge.net/"
-SRC_URI="mirror://sourceforge/dump/${MY_P}.tar.gz"
+SRC_URI="https://downloads.sourceforge.net/dump/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
 
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS="~alpha amd64 ~hppa ~ia64 ppc ppc64 sparc x86"
 # We keep uuid USE flag default dsiabled for this version. Don't forget
 # to default enable it for later versions as this is the upstream default.
-IUSE="bzip2 debug ermt libressl lzo readline selinux sqlite ssl static test uuid zlib"
+IUSE="bzip2 debug ermt lzo readline selinux sqlite ssl static test uuid zlib"
 RESTRICT="!test? ( test )"
 REQUIRED_USE="
 	ermt? ( ssl )
 	ssl? ( zlib )
-	test? ( sqlite? ( uuid ) )
-"
+	test? ( sqlite? ( uuid ) )"
 
-RDEPEND=">=sys-fs/e2fsprogs-1.27:=
-	>=sys-libs/e2fsprogs-libs-1.27:=
+RDEPEND="
+	>=sys-fs/e2fsprogs-1.27:=
 	sys-apps/util-linux
-	bzip2? ( >=app-arch/bzip2-1.0.2:= )
-	zlib? ( >=sys-libs/zlib-1.1.4:= )
-	lzo? ( dev-libs/lzo:2= )
-	sqlite? ( dev-db/sqlite:3= )
-	ermt? (
-		!libressl? ( dev-libs/openssl:0= )
-		libressl? ( dev-libs/libressl:0= )
+	bzip2? (
+		app-arch/bzip2:=
+		static? ( app-arch/bzip2[static-libs] )
 	)
-	ssl? (
-		!libressl? ( dev-libs/openssl:0= )
-		libressl? ( dev-libs/libressl:0= )
+	zlib? ( >=sys-libs/zlib-1.1.4:= )
+	lzo? (
+		dev-libs/lzo:2=
+		static? ( dev-libs/lzo:2[static-libs] )
 	)
+	sqlite? ( dev-db/sqlite:3= )
+	ermt? ( dev-libs/openssl:0= )
+	ssl? ( dev-libs/openssl:0= )
 	readline? (
 		sys-libs/readline:0=
 		sys-libs/ncurses:=
@@ -44,13 +44,7 @@ RDEPEND=">=sys-fs/e2fsprogs-1.27:=
 	)"
 DEPEND="${RDEPEND}
 	virtual/os-headers"
-BDEPEND="
-	virtual/pkgconfig
-"
-
-PATCHES=(
-	"${FILESDIR}"/${P}-openssl11.patch
-)
+BDEPEND="virtual/pkgconfig"
 
 src_configure() {
 	local myeconfargs=(
@@ -74,12 +68,17 @@ src_configure() {
 
 src_install() {
 	default
+
 	mv "${ED}"/usr/sbin/{,dump-}rmt || die
 	mv "${ED}"/usr/share/man/man8/{,dump-}rmt.8 || die
 	use ermt && newsbin rmt/ermt dump-ermt
 
 	dodoc KNOWNBUGS MAINTAINERS REPORTING-BUGS
 	dodoc -r examples
+
+	# Don't install pre-compressed files
+	gunzip "${ED}"/usr/share/doc/${PF}/examples/cron_dump_to_disk/backupskel.tar.gz \
+		|| die
 }
 
 pkg_postinst() {
diff --git a/app-arch/dump/dump-0.4.47-r2.ebuild b/app-arch/dump/dump-0.4.47-r2.ebuild
new file mode 100644
index 000000000000..9490cae1a9f6
--- /dev/null
+++ b/app-arch/dump/dump-0.4.47-r2.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit readme.gentoo-r1
+
+MY_P="${PN}-$(ver_rs 2 b)"
+
+DESCRIPTION="Dump/restore ext2fs backup utilities"
+HOMEPAGE="https://dump.sourceforge.io/"
+SRC_URI="https://downloads.sourceforge.net/dump/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~hppa ~ia64 ppc ppc64 sparc x86"
+# We keep uuid USE flag default dsiabled for this version. Don't forget
+# to default enable it for later versions as this is the upstream default.
+IUSE="bzip2 debug ermt lzo readline selinux sqlite ssl static test uuid zlib"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	ermt? ( ssl )
+	ssl? ( zlib )
+	test? ( sqlite? ( uuid ) )"
+
+RDEPEND="
+	>=sys-fs/e2fsprogs-1.27:=
+	sys-apps/util-linux
+	bzip2? (
+		app-arch/bzip2:=
+		static? ( app-arch/bzip2[static-libs] )
+	)
+	zlib? ( >=sys-libs/zlib-1.1.4:= )
+	lzo? (
+		dev-libs/lzo:2=
+		static? ( dev-libs/lzo:2[static-libs] )
+	)
+	sqlite? ( dev-db/sqlite:3= )
+	ermt? ( dev-libs/openssl:0= )
+	ssl? ( dev-libs/openssl:0= )
+	readline? (
+		sys-libs/readline:0=
+		sys-libs/ncurses:=
+		static? ( sys-libs/ncurses:=[static-libs] )
+	)"
+DEPEND="${RDEPEND}
+	virtual/os-headers"
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	local myeconfargs=(
+		--with-dumpdatespath=/etc/dumpdates
+		--with-rmtpath='$(sbindir)/rmt'
+		--enable-blkid
+		$(use_enable bzip2)
+		$(use_enable debug)
+		$(use_enable ermt)
+		$(use_enable lzo)
+		$(use_enable readline)
+		$(use_enable selinux)
+		$(use_enable sqlite)
+		$(use_enable ssl)
+		$(use_enable static static-progs)
+		$(use_enable uuid)
+		$(use_enable zlib)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	mv "${ED}"/usr/sbin/{,dump-}rmt || die
+	mv "${ED}"/usr/share/man/man8/{,dump-}rmt.8 || die
+	use ermt && newsbin rmt/ermt dump-ermt
+
+	dodoc KNOWNBUGS MAINTAINERS REPORTING-BUGS
+	dodoc -r examples
+
+	# Don't install pre-compressed files
+	gunzip "${ED}"/usr/share/doc/${PF}/examples/cron_dump_to_disk/backupskel.tar.gz \
+		|| die
+
+	local DOC_CONTENTS="dump has serious bugs
+	(see https://sourceforge.net/p/dump/bugs/162/ and
+	https://sourceforge.net/p/dump/bugs/174/). This tool should only
+	be used for restoring old backups, not for creating new ones.
+	\n\n${CATEGORY}/${PN} installs 'rmt' as 'dump-rmt'.
+	This is to avoid conflicts with app-arch/tar 'rmt'."
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}
diff --git a/app-arch/dump/dump-0.4.47-r3.ebuild b/app-arch/dump/dump-0.4.47-r3.ebuild
new file mode 100644
index 000000000000..7c53a8fa52b6
--- /dev/null
+++ b/app-arch/dump/dump-0.4.47-r3.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic readme.gentoo-r1
+
+MY_P="${PN}-$(ver_rs 2 b)"
+
+DESCRIPTION="Dump/restore ext2fs backup utilities"
+HOMEPAGE="https://dump.sourceforge.io/"
+SRC_URI="https://downloads.sourceforge.net/dump/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~hppa ~ia64 ~ppc ppc64 ~sparc x86"
+# We keep uuid USE flag default dsiabled for this version. Don't forget
+# to default enable it for later versions as this is the upstream default.
+IUSE="bzip2 debug ermt lzo readline selinux sqlite ssl static test uuid zlib"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	ermt? ( ssl )
+	ssl? ( zlib )
+	test? ( sqlite? ( uuid ) )"
+
+RDEPEND="
+	>=sys-fs/e2fsprogs-1.27:=
+	sys-apps/util-linux
+	bzip2? (
+		app-arch/bzip2:=
+		static? ( app-arch/bzip2[static-libs] )
+	)
+	zlib? ( >=sys-libs/zlib-1.1.4:= )
+	lzo? (
+		dev-libs/lzo:2=
+		static? ( dev-libs/lzo:2[static-libs] )
+	)
+	sqlite? ( dev-db/sqlite:3= )
+	ermt? ( dev-libs/openssl:0= )
+	ssl? ( dev-libs/openssl:0= )
+	readline? (
+		sys-libs/readline:0=
+		sys-libs/ncurses:=
+		static? ( sys-libs/ncurses:=[static-libs] )
+	)"
+DEPEND="${RDEPEND}
+	virtual/os-headers"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-fix-incompatible-pointer-to-integer-conversion.patch
+)
+
+src_configure() {
+	# -Werror=lto-type-mismatch
+	# https://bugs.gentoo.org/854204
+	#
+	# Abandoned upstream for 3 years. Known corruptions reported in
+	# pkg_postinst. Sourceforge software. Not bothering to report a bug...
+	filter-lto
+
+	local myeconfargs=(
+		--with-dumpdatespath=/etc/dumpdates
+		--with-rmtpath='$(sbindir)/rmt'
+		--enable-blkid
+		$(use_enable bzip2)
+		$(use_enable debug)
+		$(use_enable ermt)
+		$(use_enable lzo)
+		$(use_enable readline)
+		$(use_enable selinux)
+		$(use_enable sqlite)
+		$(use_enable ssl)
+		$(use_enable static static-progs)
+		$(use_enable uuid)
+		$(use_enable zlib)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	mv "${ED}"/usr/sbin/{,dump-}rmt || die
+	mv "${ED}"/usr/share/man/man8/{,dump-}rmt.8 || die
+	use ermt && newsbin rmt/ermt dump-ermt
+
+	dodoc KNOWNBUGS MAINTAINERS REPORTING-BUGS
+	dodoc -r examples
+
+	# Don't install pre-compressed files
+	gunzip "${ED}"/usr/share/doc/${PF}/examples/cron_dump_to_disk/backupskel.tar.gz \
+		|| die
+
+	local DOC_CONTENTS="dump has serious bugs
+	(see https://sourceforge.net/p/dump/bugs/162/ and
+	https://sourceforge.net/p/dump/bugs/174/). This tool should only
+	be used for restoring old backups, not for creating new ones.
+	\n\n${CATEGORY}/${PN} installs 'rmt' as 'dump-rmt'.
+	This is to avoid conflicts with app-arch/tar 'rmt'."
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}
diff --git a/app-arch/dump/files/dump-0.4.46-openssl11.patch b/app-arch/dump/files/dump-0.4.46-openssl11.patch
deleted file mode 100644
index db18e8190f5c..000000000000
--- a/app-arch/dump/files/dump-0.4.46-openssl11.patch
+++ /dev/null
@@ -1,91 +0,0 @@
-Index: dump-0.4b46/common/transformation_ssl.c

-===================================================================

---- dump-0.4b46.orig/common/transformation_ssl.c

-+++ dump-0.4b46/common/transformation_ssl.c

-@@ -215,7 +215,10 @@ generateIV(Transformation *xform, unsign

- 	/* to be exposed to any attacker anyway. */

- 	*saltlen = 16;

- 	if (xform->enc == 1) {

--		RAND_pseudo_bytes(salt, *saltlen);

-+		if (!RAND_bytes(salt, *saltlen) != 1) {

-+			/* PRNG not sufficiently seeded */

-+			return -1;

-+		}

- 	}

- 	memcpy(ivbuffer, salt, 16);

- 

-@@ -274,7 +277,7 @@ ssl_compress(Transformation *xform, stru

- 	digestlen = sizeof(digest);

- 

- 	/* generate salt, put it in header */

--	generateIV(xform, salt, &saltlen, iv, &ivlen);

-+	generateIV(xform, salt, &saltlen, iv, &ivlen); /* TODO: check return value */

- 	memcpy(tpbin->buf, salt, saltlen);

- 

- 	/* compress the buffer first - increase the entropy */

-@@ -351,7 +354,7 @@ ssl_decompress(Transformation *xform, st

- 

- 	// how to know salt length?

- 	memcpy(salt, src, saltlen);

--	generateIV(xform, salt, &saltlen, iv, &ivlen);

-+	generateIV(xform, salt, &saltlen, iv, &ivlen); /* TODO: check return value */

- 

- 	EVP_DecryptInit_ex(xform->state.ssl.dataCtx, xform->state.ssl.cipher,  xform->state.ssl.engine, NULL, NULL);

- 	//EVP_CIPHER_CTX_set_key_length(&ctx, 8);

-@@ -515,7 +518,7 @@ Transformation

- 		//EVP_CIPHER_CTX_rand_key(ctx, t->state.ssl.key);

- 		//EVP_CIPHER_CTX_cleanup(ctx);

- 		//EVP_CIPHER_CTX_free(ctx);

--		RAND_bytes(t->state.ssl.key, t->state.ssl.cipher->key_len);

-+		RAND_bytes(t->state.ssl.key, EVP_CIPHER_key_length(t->state.ssl.cipher));

- 	} else {

- 		// how do we get keys?

- 	}

-Index: dump-0.4b46/rmt/cipher.c

-===================================================================

---- dump-0.4b46.orig/rmt/cipher.c

-+++ dump-0.4b46/rmt/cipher.c

-@@ -23,7 +23,7 @@

- char *

- cipher(char *buf, int buflen, int do_encrypt)

- {

--	static EVP_CIPHER_CTX ctx;

-+	EVP_CIPHER_CTX *ctx = EVP_CIPHER_CTX_new();

- 	static char *out = NULL;	/* return value, grown as necessary */

- 	static int outlen = 0;

- 	static int init = 0, which, blocksize;

-@@ -71,13 +71,13 @@ cipher(char *buf, int buflen, int do_enc

- 		}

- 		EVP_BytesToKey(cipher, EVP_md5(), NULL,

- 			buf, strlen(buf), 1, key, iv);

--		EVP_CIPHER_CTX_init(&ctx);

--		EVP_CipherInit_ex(&ctx, cipher, NULL, key, iv, do_encrypt);

--		EVP_CIPHER_CTX_set_padding(&ctx, 0);	// -nopad

-+		EVP_CIPHER_CTX_init(ctx);

-+		EVP_CipherInit_ex(ctx, cipher, NULL, key, iv, do_encrypt);

-+		EVP_CIPHER_CTX_set_padding(ctx, 0);	// -nopad

- 		OPENSSL_cleanse(buf, sizeof buf);

- 		OPENSSL_cleanse(key, sizeof key);

- 		OPENSSL_cleanse(iv, sizeof iv);

--		blocksize = EVP_CIPHER_CTX_block_size(&ctx);

-+		blocksize = EVP_CIPHER_CTX_block_size(ctx);

- 		which = do_encrypt;

- 		init = 1;

- 	}

-@@ -95,7 +95,7 @@ cipher(char *buf, int buflen, int do_enc

- 		outlen = (buflen+blocksize) * 2;

- 		out = realloc(out, outlen);

- 	}

--	if (!EVP_CipherUpdate(&ctx, out, &n, buf, buflen)) {

-+	if (!EVP_CipherUpdate(ctx, out, &n, buf, buflen)) {

- 		syslog(LOG_ERR, "EVP_CipherUpdate failed");

- 		errno = EINVAL;

- 		return NULL;

-@@ -106,6 +106,7 @@ cipher(char *buf, int buflen, int do_enc

- 		return NULL;

- 	}

- 	// assert(ctx->buf_len == 0);

-+	EVP_CIPHER_CTX_free(ctx);

- 	return out;

- }

- 

diff --git a/app-arch/dump/files/dump-fix-incompatible-pointer-to-integer-conversion.patch b/app-arch/dump/files/dump-fix-incompatible-pointer-to-integer-conversion.patch
new file mode 100644
index 000000000000..220e37bb7f57
--- /dev/null
+++ b/app-arch/dump/files/dump-fix-incompatible-pointer-to-integer-conversion.patch
@@ -0,0 +1,25 @@
+From: listout <listout@protonmail.com>
+Date: Mon, 17 Apr 2023 12:36:40 +0530
+Subject: [PATCH] Fix incompatible pointer to integer conversion
+
+transformation_null was initializing one of it's elements with NULL
+which is zero type casted to void. Hence, instead of initializing with
+NULL, now we are initializing that element with zero.
+
+Refer: https://bugs.gentoo.org/874675
+
+Signed-off-by: listout <listout@protonmail.com>
+--- a/common/transformation_null.c
++++ b/common/transformation_null.c
+@@ -81,7 +81,7 @@ null_decompress(Transformation *xform, struct tapebuf *tpbin, unsigned long *des
+ Transformation transformation_null =
+ {
+ 	0,
+-	NULL,
++	0,
+ 	"null",
+ 	0,
+ 	&null_initialize,
+--
+2.39.2
+
diff --git a/app-arch/dump/metadata.xml b/app-arch/dump/metadata.xml
index 256f76fc5bff..762d33d0a55f 100644
--- a/app-arch/dump/metadata.xml
+++ b/app-arch/dump/metadata.xml
@@ -1,5 +1,5 @@
 <?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 	<maintainer type="project">
 		<email>base-system@gentoo.org</email>