1 files changed, 47 insertions, 0 deletions
diff --git a/app-arch/gnome-autoar/gnome-autoar-0.4.0.ebuild b/app-arch/gnome-autoar/gnome-autoar-0.4.0.ebuild
new file mode 100644
index 000000000000..aa09c033b7e3
--- /dev/null
+++ b/app-arch/gnome-autoar/gnome-autoar-0.4.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome.org meson vala
+
+DESCRIPTION="Automatic archives creating and extracting library"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-autoar"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="gtk gtk-doc +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=app-arch/libarchive-3.4.0
+	>=dev-libs/glib-2.35.6:2
+	gtk? ( >=x11-libs/gtk+-3.2:3[introspection?] )
+	introspection? ( >=dev-libs/gobject-introspection-1.30.0:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-util/meson-0.58
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk)
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use test tests)
+		$(meson_use gtk-doc gtk_doc)
+	)
+	meson_src_configure
+}