1 files changed, 33 insertions, 0 deletions
diff --git a/app-cdr/mirage2iso/mirage2iso-0.4.2.ebuild b/app-cdr/mirage2iso/mirage2iso-0.4.2.ebuild
new file mode 100644
index 000000000000..97e1fa1f6d38
--- /dev/null
+++ b/app-cdr/mirage2iso/mirage2iso-0.4.2.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="CD/DVD image converter using libmirage"
+HOMEPAGE="https://github.com/mgorny/mirage2iso/"
+SRC_URI="https://github.com/mgorny/${PN}/releases/download/v${PV}/${P}.tar.xz
+	test? ( https://github.com/mgorny/${PN}/releases/download/v${PV}/${P}-tests.tar.xz )"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="pinentry test"
+
+COMMON_DEPEND=">=dev-libs/libmirage-2.0.0:0=
+	dev-libs/glib:2=
+	pinentry? ( dev-libs/libassuan:0= )"
+DEPEND="${COMMON_DEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig"
+RDEPEND="${COMMON_DEPEND}
+	pinentry? ( app-crypt/pinentry )"
+
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	local myconf=(
+		$(use_with pinentry libassuan)
+	)
+
+	econf "${myconf[@]}"
+}