1 files changed, 44 insertions, 0 deletions
diff --git a/app-crypt/gpa/gpa-0.10.0-r1.ebuild b/app-crypt/gpa/gpa-0.10.0-r1.ebuild
new file mode 100644
index 000000000000..41a134a6faf0
--- /dev/null
+++ b/app-crypt/gpa/gpa-0.10.0-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools xdg
+
+DESCRIPTION="The GNU Privacy Assistant (GPA) is a graphical user interface for GnuPG"
+HOMEPAGE="http://gpa.wald.intevation.org"
+SRC_URI="mirror://gnupg/${PN}/${P}.tar.bz2"
+# Backport of upstream changes to 0.10.0
+SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-autoconf.patch.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha amd64 ppc ppc64 sparc x86"
+IUSE="nls"
+
+RDEPEND="
+	>=app-crypt/gnupg-2:=
+	>=app-crypt/gpgme-1.11.1:=
+	>=dev-libs/libassuan-1.1.0:=
+	>=dev-libs/libgpg-error-1.4:=
+	>=x11-libs/gtk+-2.10.0:2=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${WORKDIR}"/${P}-autoconf.patch
+)
+
+src_prepare() {
+	default
+	sed -i 's/Application;//' gpa.desktop
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		GPGKEYS_LDAP="/usr/libexec/gpgkeys_ldap"
+}