5 files changed, 77 insertions, 0 deletions
diff --git a/app-emacs/geiser-guile/Manifest b/app-emacs/geiser-guile/Manifest
new file mode 100644
index 000000000000..15bcbf525c5d
--- /dev/null
+++ b/app-emacs/geiser-guile/Manifest
@@ -0,0 +1 @@
+DIST geiser-guile-0.28.1.tar.bz2 15806 BLAKE2B 3484fda74ea84eadaf2c20dca48c7f66a4fa4966ec90246f29e9ff1ca9eb5c0f87fd7f724c84c4685d05b9edec527893e1ab9dc1f8d4f6eade2ddb6bad4ad192 SHA512 1147cdeac9aba565921efd094725309764ac17be34533ba62f18a866e8b6511a0896e3ea0dd17f4d408f5c99ce05a0779d370c0dd35e0353efd9765c7eb44831
diff --git a/app-emacs/geiser-guile/files/50geiser-guile-gentoo.el b/app-emacs/geiser-guile/files/50geiser-guile-gentoo.el
new file mode 100644
index 000000000000..c9ac820301e1
--- /dev/null
+++ b/app-emacs/geiser-guile/files/50geiser-guile-gentoo.el
@@ -0,0 +1,7 @@
+(add-to-list 'load-path "@SITELISP@")
+(autoload 'connect-to-guile "geiser-guile"
+  "Start a Guile REPL connected to a remote process." t)
+(autoload 'run-guile "geiser-guile"
+  "Start a Geiser Guile REPL." t)
+(autoload 'switch-to-guile "geiser-guile"
+  "Start a Geiser Guile REPL, or switch to a running one." t)
diff --git a/app-emacs/geiser-guile/files/geiser-guile-guile-scheme-src-dir.patch b/app-emacs/geiser-guile/files/geiser-guile-guile-scheme-src-dir.patch
new file mode 100644
index 000000000000..e86ffaa5edb7
--- /dev/null
+++ b/app-emacs/geiser-guile/files/geiser-guile-guile-scheme-src-dir.patch
@@ -0,0 +1,12 @@
+index db42945..2a6537c 100644
+--- a/geiser-guile.el
++++ b/geiser-guile.el
+@@ -141,7 +141,7 @@ effect on new REPLs.  For existing ones, use the command
+     geiser-guile-binary))
+ 
+ (defvar geiser-guile-scheme-dir
+-  (expand-file-name "src" (file-name-directory load-file-name))
++  (expand-file-name "src" "@SITEETC@")
+   "Directory where the Guile scheme geiser modules are installed.")
+ 
+ (defvar-local geiser-guile-scheme-local-dir
diff --git a/app-emacs/geiser-guile/geiser-guile-0.28.1.ebuild b/app-emacs/geiser-guile/geiser-guile-0.28.1.ebuild
new file mode 100644
index 000000000000..01ecaff290dc
--- /dev/null
+++ b/app-emacs/geiser-guile/geiser-guile-0.28.1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp
+
+DESCRIPTION="Guile's implementation of the Geiser protocols"
+HOMEPAGE="https://gitlab.com/emacs-geiser/guile/"
+SRC_URI="https://gitlab.com/emacs-geiser/guile/-/archive/${PV}/guile-${PV}.tar.bz2
+	-> ${P}.tar.bz2"
+S="${WORKDIR}"/guile-${PV}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~x86"
+
+BDEPEND="app-emacs/geiser"
+RDEPEND="
+	${BDEPEND}
+	dev-scheme/guile
+"
+
+DOCS=( readme.org )
+PATCHES=( "${FILESDIR}"/${PN}-guile-scheme-src-dir.patch )
+ELISP_TEXINFO="${PN}.texi"
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	elisp_src_prepare
+
+	sed "s|@SITEETC@|${EPREFIX}${SITEETC}/${PN}|" -i ${PN}.el || die
+}
+
+src_install() {
+	elisp_src_install
+
+	insinto ${SITEETC}/${PN}
+	doins -r src
+}
diff --git a/app-emacs/geiser-guile/metadata.xml b/app-emacs/geiser-guile/metadata.xml
new file mode 100644
index 000000000000..7698a7c42f05
--- /dev/null
+++ b/app-emacs/geiser-guile/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="project">
+    <email>gnu-emacs@gentoo.org</email>
+    <name>Gentoo GNU Emacs project</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>scheme@gentoo.org</email>
+    <name>Gentoo Scheme Project</name>
+  </maintainer>
+  <upstream>
+    <bugs-to>https://gitlab.com/emacs-geiser/guile/-/issues/</bugs-to>
+    <remote-id type="gitlab">emacs-geiser/guile</remote-id>
+  </upstream>
+</pkgmetadata>