1 files changed, 45 insertions, 0 deletions
diff --git a/app-emacs/nxml-libvirt-schemas/nxml-libvirt-schemas-10.2.0.ebuild b/app-emacs/nxml-libvirt-schemas/nxml-libvirt-schemas-10.2.0.ebuild
new file mode 100644
index 000000000000..16945cb9e2ff
--- /dev/null
+++ b/app-emacs/nxml-libvirt-schemas/nxml-libvirt-schemas-10.2.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Packages which get releases together:
+# app-emacs/nxml-libvirt-schemas
+# dev-python/libvirt-python
+# dev-perl/Sys-Virt
+# app-emulation/libvirt
+# Please bump them together!
+
+inherit elisp
+
+MY_P="libvirt-${PV}"
+DESCRIPTION="Extension for nxml-mode with libvirt schemas"
+HOMEPAGE="https://www.libvirt.org/"
+SRC_URI="https://libvirt.org/sources/${MY_P}.tar.xz"
+S="${WORKDIR}/${MY_P%-rc*}/src/conf/schemas"
+
+# This is the license of the package, but the schema files are
+# provided without license, maybe it's bad.
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# Yes this requires Java, but I'd rather not repackage this, if you
+# know something better in C, I'll be glad to use that.
+BDEPEND="app-text/trang"
+
+SITEFILE="60${PN}-gentoo.el"
+
+src_compile() {
+	emake -f - <<'EOF'
+all: $(patsubst %.rng,%.rnc,$(wildcard *.rng))
+%.rnc: %.rng
+	trang -I rng -O rnc $< $@
+EOF
+}
+
+src_install() {
+	insinto "${SITEETC}/${PN}"
+	doins "${FILESDIR}"/schemas.xml *.rnc
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+}