1 files changed, 39 insertions, 0 deletions
diff --git a/app-emulation/docker-machine/docker-machine-0.13.0.ebuild b/app-emulation/docker-machine/docker-machine-0.13.0.ebuild
new file mode 100644
index 000000000000..1697e3defa68
--- /dev/null
+++ b/app-emulation/docker-machine/docker-machine-0.13.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGO_PN=github.com/docker/machine
+
+if [[ ${PV} = *9999* ]]; then
+	inherit golang-vcs
+else
+	KEYWORDS="~amd64"
+	EGIT_COMMIT="v${PV}"
+	SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	inherit golang-vcs-snapshot
+fi
+inherit golang-build
+
+DESCRIPTION="Machine management for a container-centric world"
+HOMEPAGE="https://docs.docker.com/machine/"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="hardened"
+RESTRICT="test"
+S=${WORKDIR}/${P}/src/${EGO_PN}
+
+src_prepare() {
+	default
+	# don't pre-strip binaries
+	sed -e 's|\(GO_LDFLAGS := $(GO_LDFLAGS) -w\) -s|\1|' -i mk/main.mk ||die
+}
+
+src_compile() {
+	CGO_LDFLAGS="$(usex hardened '-fno-PIC ' '')" GOPATH="${WORKDIR}/${P}" emake build || die
+}
+
+src_install() {
+	dobin bin/*
+	dodoc CHANGELOG.md CONTRIBUTING.md README.md ROADMAP.md
+}