summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'app-misc/byobu/byobu-5.113.ebuild')
-rw-r--r--app-misc/byobu/byobu-5.113.ebuild44
1 files changed, 44 insertions, 0 deletions
diff --git a/app-misc/byobu/byobu-5.113.ebuild b/app-misc/byobu/byobu-5.113.ebuild
new file mode 100644
index 00000000000..7bd23b5ebff
--- /dev/null
+++ b/app-misc/byobu/byobu-5.113.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-single-r1
+
+DESCRIPTION="A set of profiles for the GNU Screen console window manager (app-misc/screen)"
+HOMEPAGE="http://byobu.co"
+SRC_URI="https://launchpad.net/${PN}/trunk/${PV}/+download/${P/-/_}.orig.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="screen"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+ dev-libs/newt[${PYTHON_USEDEP}]
+ screen? ( app-misc/screen )
+ !screen? ( app-misc/tmux )"
+
+src_prepare() {
+ default
+
+ python_fix_shebang .
+
+ # Set default system backend to screen
+ if use screen ; then
+ sed -i -e 's/#\(BYOBU_BACKEND\).*/\1="screen"/' etc/byobu/backend || die
+ fi
+}
+
+src_install() {
+ default
+
+ # Create symlinks for backends
+ dosym ${PN} /usr/bin/${PN}-screen
+ dosym ${PN} /usr/bin/${PN}-tmux
+
+ docompress -x /usr/share/doc/${PN}
+}