1 files changed, 69 insertions, 0 deletions
diff --git a/app-portage/gentoolkit/gentoolkit-0.5.1.ebuild b/app-portage/gentoolkit/gentoolkit-0.5.1.ebuild
new file mode 100644
index 000000000000..a05cb33f75d4
--- /dev/null
+++ b/app-portage/gentoolkit/gentoolkit-0.5.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{7,8,9} pypy3 )
+PYTHON_REQ_USE="xml(+),threads(+)"
+
+inherit distutils-r1
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/gentoolkit.git"
+	inherit git-r3
+else
+	SRC_URI="https://gitweb.gentoo.org/proj/gentoolkit.git/snapshot/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="Collection of administration scripts for Gentoo"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Portage-Tools"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+DEPEND="
+	sys-apps/portage[${PYTHON_USEDEP}]"
+RDEPEND="${DEPEND}
+	sys-apps/gawk
+	sys-apps/gentoo-functions"
+
+distutils_enable_tests setup.py
+
+python_prepare_all() {
+	python_setup
+	echo VERSION="${PVR}" "${PYTHON}" setup.py set_version
+	VERSION="${PVR}" "${PYTHON}" setup.py set_version
+	distutils-r1_python_prepare_all
+
+	if use prefix-guest ; then
+		# use correct repo name, bug #632223
+		sed -i \
+			-e "/load_profile_data/s/repo='gentoo'/repo='gentoo_prefix'/" \
+			pym/gentoolkit/profile.py || die
+	fi
+}
+
+pkg_postinst() {
+	# Create cache directory for revdep-rebuild
+	mkdir -p -m 0755 "${EROOT}"/var/cache
+	mkdir -p -m 0700 "${EROOT}"/var/cache/revdep-rebuild
+
+	# Only show the elog information on a new install
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		elog
+		elog "For further information on gentoolkit, please read the gentoolkit"
+		elog "guide: https://wiki.gentoo.org/wiki/Gentoolkit"
+		elog
+		elog "Another alternative to equery is app-portage/portage-utils"
+		elog
+		elog "Additional tools that may be of interest:"
+		elog
+		elog "    app-admin/eclean-kernel"
+		elog "    app-portage/diffmask"
+		elog "    app-portage/flaggie"
+		elog "    app-portage/portpeek"
+		elog "    app-portage/smart-live-rebuild"
+	fi
+}