1 files changed, 59 insertions, 0 deletions
diff --git a/app-text/dvipsk/dvipsk-2020.1_p20200406.ebuild b/app-text/dvipsk/dvipsk-2020.1_p20200406.ebuild
new file mode 100644
index 000000000000..0fb2ae9d07bf
--- /dev/null
+++ b/app-text/dvipsk/dvipsk-2020.1_p20200406.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit texlive-common
+
+DESCRIPTION="DVI-to-PostScript translator"
+HOMEPAGE="http://tug.org/texlive/"
+SRC_URI="mirror://gentoo/texlive-${PV#*_p}-source.tar.xz"
+
+TL_VERSION=2020
+EXTRA_TL_MODULES="dvips"
+EXTRA_TL_DOC_MODULES="dvips.doc"
+
+for i in ${EXTRA_TL_MODULES} ; do
+	SRC_URI="${SRC_URI} https://dev.gentoo.org/~zlogene/texlive/texlive-module-${i}-${TL_VERSION}.tar.xz"
+done
+
+SRC_URI="${SRC_URI} doc? ( "
+for i in ${EXTRA_TL_DOC_MODULES} ; do
+	SRC_URI="${SRC_URI} https://dev.gentoo.org/~zlogene/texlive/texlive-module-${i}-${TL_VERSION}.tar.xz"
+done
+SRC_URI="${SRC_URI} ) "
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc source"
+
+DEPEND=">=dev-libs/kpathsea-6.2.1"
+
+BDEPEND="virtual/pkgconfig"
+
+S=${WORKDIR}/texlive-${PV#*_p}-source/texk/${PN}
+
+src_configure() {
+	econf --with-system-kpathsea
+}
+
+src_install() {
+	emake DESTDIR="${D}" prologdir="${EPREFIX}/usr/share/texmf-dist/dvips/base" install
+
+	dodir /usr/share # just in case
+	cp -pR "${WORKDIR}"/texmf-dist "${ED}/usr/share/" || die "failed to install texmf trees"
+	if use source ; then
+		cp -pR "${WORKDIR}"/tlpkg "${ED}/usr/share/" || die "failed to install tlpkg files"
+	fi
+
+	dodoc AUTHORS ChangeLog NEWS README TODO
+}
+
+pkg_postinst() {
+	etexmf-update
+}
+
+pkg_postrm() {
+	etexmf-update
+}