1 files changed, 54 insertions, 0 deletions
diff --git a/app-text/libebook/libebook-0.1.3.ebuild b/app-text/libebook/libebook-0.1.3.ebuild
new file mode 100644
index 000000000000..4458a48c0262
--- /dev/null
+++ b/app-text/libebook/libebook-0.1.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_PN="libe-book"
+MY_P="${MY_PN}-${PV}"
+
+inherit autotools
+
+DESCRIPTION="Library parsing various ebook formats"
+HOMEPAGE="http://www.sourceforge.net/projects/libebook/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc test tools"
+
+RDEPEND="
+	dev-libs/icu:=
+	dev-libs/librevenge
+	dev-libs/libxml2
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	dev-util/gperf
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cppunit )
+"
+RDEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--disable-werror \
+		$(use_with doc docs) \
+		$(use_enable test tests) \
+		$(use_with tools)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}