1 files changed, 0 insertions, 89 deletions
diff --git a/dev-ada/gprbuild/gprbuild-2017-r2.ebuild b/dev-ada/gprbuild/gprbuild-2017-r2.ebuild
deleted file mode 100644
index 79897043cf6b..000000000000
--- a/dev-ada/gprbuild/gprbuild-2017-r2.ebuild
+++ /dev/null
@@ -1,89 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-ADA_COMPAT=( gnat_201{6,7} )
-
-inherit ada toolchain-funcs multiprocessing
-
-MYP=${PN}-gpl-${PV}
-
-DESCRIPTION="Multi-Language Management"
-HOMEPAGE="http://libre.adacore.com/"
-SRC_URI="
-	http://mirrors.cdn.adacore.com/art/591c45e2c7a447af2deecff7
-		-> ${MYP}-src.tar.gz
-	http://mirrors.cdn.adacore.com/art/591aeb88c7a4473fcbb154f8
-		-> xmlada-gpl-${PV}-src.tar.gz"
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-REQUIRED_USE="${ADA_REQUIRED_USE}"
-
-DEPEND="${ADA_DEPS}"
-RDEPEND="${DEPEND}"
-
-S="${WORKDIR}"/${MYP}-src
-
-PATCHES=(
-	"${FILESDIR}"/${P}-gentoo.patch
-	"${FILESDIR}"/${P}-config.patch
-)
-
-src_prepare() {
-	default
-	sed -i \
-		-e "s:@VER@:${GCC_PV}:g" \
-		share/gprconfig/compilers.xml \
-		share/gprconfig/gnat.xml \
-		share/gprconfig/c.xml \
-		share/gprconfig/linker.xml \
-		|| die
-	sed -i \
-		-e "s:@GNATBIND@:${GNATBIND}:g" \
-		src/gprlib.adb \
-		|| die
-	if use ada_target_gnat_2016; then
-		sed -i \
-			-e 's:"-no-pie", ::g' \
-			share/gprconfig/linker.xml \
-			|| die
-	fi
-}
-
-src_configure() {
-	emake prefix="${D}"/usr setup
-}
-
-bin_progs="gprbuild gprconfig gprclean gprinstall gprname gprls"
-lib_progs="gprlib gprbind"
-
-src_compile() {
-	local xmlada_src="../xmlada-gpl-${PV}-src"
-	incflags="-Isrc -Igpr/src -I${xmlada_src}/sax -I${xmlada_src}/dom \
-		-I${xmlada_src}/schema -I${xmlada_src}/unicode \
-		-I${xmlada_src}/input_sources"
-	${GCC} -c ${CFLAGS} gpr/src/gpr_imports.c -o gpr_imports.o || die
-	for bin in ${bin_progs}; do
-		${GNATMAKE} -j$(makeopts_jobs) ${incflags} $ADAFLAGS ${bin}-main \
-			-o ${bin} -largs gpr_imports.o || die
-	done
-	for lib in $lib_progs; do
-		${GNATMAKE} -j$(makeopts_jobs) ${incflags} ${lib} $ADAFLAGS \
-			-largs gpr_imports.o || die
-	done
-}
-
-src_install() {
-	dobin ${bin_progs}
-	exeinto /usr/libexec/gprbuild
-	doexe ${lib_progs}
-	insinto /usr/share/gprconfig
-	doins share/gprconfig/*
-	insinto /usr/share/gpr
-	doins share/_default.gpr
-	einstalldocs
-}