1 files changed, 0 insertions, 85 deletions
diff --git a/dev-games/ode/ode-0.12.ebuild b/dev-games/ode/ode-0.12.ebuild
deleted file mode 100644
index c5e93ccbf22c..000000000000
--- a/dev-games/ode/ode-0.12.ebuild
+++ /dev/null
@@ -1,85 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-DESCRIPTION="Open Dynamics Engine SDK"
-HOMEPAGE="http://ode.org/"
-SRC_URI="mirror://sourceforge/opende/${P}.tar.bz2"
-
-LICENSE="|| ( LGPL-2.1 BSD )"
-SLOT="0"
-KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
-IUSE="debug doc double-precision examples gyroscopic static-libs"
-
-RDEPEND="
-	examples? (
-		virtual/opengl
-	)
-"
-DEPEND="${RDEPEND}"
-BDEPEND="doc? ( app-doc/doxygen )"
-
-DOCS=( CHANGELOG.txt README.txt )
-
-src_prepare() {
-	default
-
-	sed -i \
-		-e "s:\$.*/drawstuff/textures:/usr/share/doc/${PF}/examples:" \
-		drawstuff/src/Makefile.in \
-		ode/demo/Makefile.in || die
-}
-
-src_configure() {
-	# use bash (bug #335760)
-	CONFIG_SHELL=/bin/bash \
-	econf \
-		--enable-shared \
-		$(use_enable static-libs static) \
-		$(use_enable debug asserts) \
-		$(use_enable double-precision) \
-		$(use_enable examples demos) \
-		$(use_enable gyroscopic) \
-		$(use_with examples drawstuff X11)
-}
-
-src_compile() {
-	emake
-
-	if use doc ; then
-		cd ode/doc || die
-		doxygen Doxyfile || die
-	fi
-}
-
-src_install() {
-	default
-
-	find "${ED}" -name '*.la' -delete || die
-
-	if use doc ; then
-		docinto html
-		dodoc docs/*
-	fi
-
-	if use examples ; then
-		cd ode/demo || die
-
-		exeinto /usr/share/doc/${PF}/examples
-
-		local f
-		for f in *.c* ; do
-			doexe .libs/${f%.*}
-		done
-
-		cd ../.. || die
-
-		doexe drawstuff/dstest/dstest
-		docinto examples
-		dodoc ode/demo/*.{c,cpp,h} \
-			drawstuff/textures/*.ppm \
-			drawstuff/dstest/dstest.cpp \
-			drawstuff/src/{drawstuff.cpp,internal.h,x11.cpp}
-	fi
-}