1 files changed, 47 insertions, 0 deletions
diff --git a/dev-lang/execline/execline-2.9.2.1.ebuild b/dev-lang/execline/execline-2.9.2.1.ebuild
new file mode 100644
index 000000000000..99842e4ae590
--- /dev/null
+++ b/dev-lang/execline/execline-2.9.2.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="A non-interactive scripting language"
+HOMEPAGE="https://www.skarnet.org/software/execline/"
+SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~riscv ~x86"
+
+RDEPEND=">=dev-libs/skalibs-2.13.0.0:="
+DEPEND="${RDEPEND}"
+
+HTML_DOCS=( doc/. )
+
+src_prepare() {
+	default
+
+	# Avoid QA warning for LDFLAGS addition
+	sed -i -e 's/.*-Wl,--hash-style=both$/:/' configure || die
+
+	sed -i -e '/AR := /d' -e '/RANLIB := /d' Makefile || die
+}
+
+src_configure() {
+	tc-export AR CC RANLIB
+
+	local myconf=(
+		--bindir=/bin
+		--dynlibdir="/$(get_libdir)"
+		--libdir="/usr/$(get_libdir)/${PN}"
+		--with-dynlib="/$(get_libdir)"
+		--with-lib="/usr/$(get_libdir)/skalibs"
+		--with-sysdeps="/usr/$(get_libdir)/skalibs"
+		--enable-shared
+		--disable-allstatic
+		--disable-static
+		--disable-static-libc
+	)
+
+	econf "${myconf[@]}"
+}