1 files changed, 47 insertions, 0 deletions
diff --git a/dev-libs/FBGEMM/FBGEMM-2022.01.13.ebuild b/dev-libs/FBGEMM/FBGEMM-2022.01.13.ebuild
new file mode 100644
index 000000000000..51c233d44e8d
--- /dev/null
+++ b/dev-libs/FBGEMM/FBGEMM-2022.01.13.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+CommitId=135412d2646f3bd753c8f1cfd33616110bbccd27
+
+DESCRIPTION="Facebook GEneral Matrix Multiplication"
+HOMEPAGE="https://github.com/pytorch/FBGEMM"
+SRC_URI="https://github.com/pytorch/${PN}/archive/${CommitId}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+DEPEND="
+	dev-libs/asmjit
+	dev-libs/cpuinfo
+"
+RDEPEND="${DEPEND}"
+BDEPEND="test? ( dev-cpp/gtest )"
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}"/${PN}-${CommitId}
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gentoo.patch
+)
+
+src_prepare() {
+	rm test/RowWiseSparseAdagradFusedTest.cc || die
+	rm test/SparseAdagradTest.cc || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DFBGEMM_LIBRARY_TYPE=shared
+		-DFBGEMM_BUILD_BENCHMARKS=OFF
+		-DFBGEMM_BUILD_TESTS=$(usex test ON OFF)
+	)
+	cmake_src_configure
+}