1 files changed, 66 insertions, 0 deletions
diff --git a/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-18.20.606296.ebuild b/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-18.20.606296.ebuild
new file mode 100644
index 000000000000..614f397a1b7e
--- /dev/null
+++ b/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-18.20.606296.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit unpacker
+
+SUPER_PN='amdgpu-pro'
+MY_PV=$(ver_rs 2 '-')
+
+DESCRIPTION="Proprietary OpenCL implementation for AMD GPUs"
+HOMEPAGE="https://support.amd.com/en-us/kb-articles/Pages/Radeon-Software-for-Linux-Release-Notes.aspx"
+SRC_URI="${SUPER_PN}-${MY_PV}.tar.xz"
+
+LICENSE="AMD-GPU-PRO-EULA"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RESTRICT="mirror fetch strip"
+
+DEPEND=""
+RDEPEND="dev-libs/ocl-icd"
+
+QA_PREBUILT="/opt/${SUPER_PN}/lib*/*"
+
+S="${WORKDIR}/${SUPER_PN}-${MY_PV}"
+
+pkg_nofetch() {
+	local pkgver=$(ver_cut 1-2)
+	einfo "Please download the Radeon Software for Linux Driver ${pkgver} for Ubuntu 16 from"
+	einfo "    ${HOMEPAGE}"
+	einfo "The archive should then be placed into ${DISTDIR}."
+}
+
+src_unpack() {
+	default
+
+	cd "${S}" || die
+	unpack_deb opencl-orca-amdgpu-pro-icd_${MY_PV}_amd64.deb
+}
+
+src_install() {
+	into "/opt/amdgpu"
+	dolib.so opt/${SUPER_PN}/lib/x86_64-linux-gnu/*
+
+	insinto /etc/OpenCL/vendors/
+	echo "/opt/amdgpu/$(get_libdir)/libamdocl-orca64.so" > "${SUPER_PN}.icd" || die "Failed to generate ICD file"
+	doins "${SUPER_PN}.icd"
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		ewarn "Please note that using proprietary OpenCL libraries together with the"
+		ewarn "Open Source amdgpu stack is not officially supported by AMD. Do not ask them"
+		ewarn "for support in case of problems with this package."
+		ewarn ""
+		ewarn "Furthermore, if you have the whole AMDGPU-Pro stack installed this package"
+		ewarn "will almost certainly conflict with it. This might change once AMDGPU-Pro"
+		ewarn "has become officially supported by Gentoo."
+	fi
+
+	elog "AMD OpenCL driver relies on dev-libs/ocl-icd to work. To enable it, please run"
+	elog ""
+	elog "    eselect opencl set ocl-icd"
+	elog ""
+}