1 files changed, 33 insertions, 0 deletions
diff --git a/dev-libs/flatbuffers/flatbuffers-2.0.0-r1.ebuild b/dev-libs/flatbuffers/flatbuffers-2.0.0-r1.ebuild
new file mode 100644
index 000000000000..4be03e4e789d
--- /dev/null
+++ b/dev-libs/flatbuffers/flatbuffers-2.0.0-r1.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Memory efficient serialization library"
+HOMEPAGE="https://google.github.io/flatbuffers/"
+SRC_URI="https://github.com/google/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+# From 1.2.0->2.0.0, incremented SONAME, although the interface didn't actually change.
+# (Apparently to adopt semver.)
+SLOT="0/2"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="static-libs test"
+
+RESTRICT="!test? ( test )"
+
+DOCS=( readme.md )
+
+src_configure() {
+	local mycmakeargs=(
+		-DFLATBUFFERS_BUILD_FLATLIB=$(usex static-libs)
+		-DFLATBUFFERS_BUILD_SHAREDLIB=ON
+		-DFLATBUFFERS_BUILD_TESTS=$(usex test)
+	)
+
+	use elibc_musl && mycmakeargs+=( -DFLATBUFFERS_LOCALE_INDEPENDENT=0 )
+
+	cmake_src_configure
+}