1 files changed, 60 insertions, 0 deletions
diff --git a/dev-libs/libgit2-glib/libgit2-glib-0.27.7.ebuild b/dev-libs/libgit2-glib/libgit2-glib-0.27.7.ebuild
new file mode 100644
index 000000000000..ab9ce3117461
--- /dev/null
+++ b/dev-libs/libgit2-glib/libgit2-glib-0.27.7.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{3_4,3_5,3_6,3_7} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome.org meson python-r1 vala
+
+DESCRIPTION="Git library for GLib"
+HOMEPAGE="https://wiki.gnome.org/Projects/Libgit2-glib"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="python +ssh +vala"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# libgit2-glib is now compatible with SONAME 26 and 27 of libgit2.
+RDEPEND="
+	>=dev-libs/gobject-introspection-0.10.1:=
+	>=dev-libs/glib-2.44.0:2
+	<dev-libs/libgit2-0.28:0=[ssh?]
+	>=dev-libs/libgit2-0.26.0:0
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		# apparently broken; fails to build
+		-Dgtk_doc=false
+		# we install python scripts manually
+		-Dpython=false
+		-Dssh=$(usex ssh true false)
+		-Dvapi=$(usex vala true false)
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use python ; then
+		python_moduleinto gi.overrides
+		python_foreach_impl python_domodule libgit2-glib/Ggit.py
+	fi
+}