1 files changed, 41 insertions, 0 deletions
diff --git a/dev-python/cheetah3/cheetah3-3.2.6_p2.ebuild b/dev-python/cheetah3/cheetah3-3.2.6_p2.ebuild
new file mode 100644
index 000000000000..a4c89574fcc1
--- /dev/null
+++ b/dev-python/cheetah3/cheetah3-3.2.6_p2.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="Python-powered template engine and code generator"
+HOMEPAGE="https://cheetahtemplate.org/ https://pypi.org/project/Cheetah3/"
+SRC_URI="
+	https://github.com/CheetahTemplate3/${PN}/archive/${PV/_p/.post}.tar.gz
+		-> ${MY_P}.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+SLOT="0"
+
+RDEPEND="
+	dev-python/markdown[${PYTHON_USEDEP}]
+	!dev-python/cheetah
+"
+BDEPEND="${RDEPEND}"
+
+DOCS=( ANNOUNCE.rst README.rst TODO )
+
+python_prepare_all() {
+	# Disable broken tests.
+	sed -i -e "/Unicode/d" -i Cheetah/Tests/Test.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${EPYTHON}" Cheetah/Tests/Test.py || die "Tests fail with ${EPYTHON}"
+}