3 files changed, 72 insertions, 47 deletions
diff --git a/dev-python/eyeD3/Manifest b/dev-python/eyeD3/Manifest
index f34a21804178..1206902a6c2d 100644
--- a/dev-python/eyeD3/Manifest
+++ b/dev-python/eyeD3/Manifest
@@ -1,2 +1,2 @@
-DIST eyeD3-0.9.6.tar.gz 250445 BLAKE2B 11f8bef4b17af07f08144e922634e4c6e467bd8856da9d445a70006b5bf32d442a52e234845a3f146129403fcc16047cc759102b93c433a0466bf0afd9576230 SHA512 0c993e9bf0a27ca41a8a2964a3347a6b0ffa472f833b3dada39ae09a5a2b40e0afb6bfd8c0ea5ed71d3dc2bf3cd062c1fb5fe79abe6ad867221b779786247173
-DIST eyeD3-test-data.tgz 97281754 BLAKE2B 9b667a5f8be157ace06d773d575c08f4a8e8b7a7b81ba9cb39b1e2c924b2e3f98597607ed3076b13150e02ef7768e89d1ff8a9913021e5f4b9ac6b59344ed397 SHA512 937971dcefc53812c59adb97df27d200e92de04e12391c735ab85cd547e2a168aa1212d88c206ec71ac2fa85a504a9faa91dcc444b45149aca7c8f3a794e9a95
+DIST eyeD3-0.9.7.gh.tar.gz 249705 BLAKE2B b015ab5f7269de8f32830153b848e9a862328515e29f5d1a9cd5739d57a1c0ee63efc93cd3849ceca51b8f67d8eaf1746ab145baf16cda7e7b19bbb8e1249982 SHA512 863ce609ea939588e246d48c6d31f9688049334f874a4c400c02777bbef7379b6403150e7459430c92cff8047d45e33cbaa406b3d6e5b2cf3f9d7d7201438c1f
+DIST eyeD3-test-data-r1.tgz 97336666 BLAKE2B e982f21ba29aaca15c6975a836bed322d5203bca57b93ab0c9343de13259d9e2f56b98e5e7402ccf9138a9dc79951e68c4b37cd2c891d2c9e94815256d49adc4 SHA512 4e6daca06380492c0048f1ffd94d92e511fc3695b3e5f64f805d3f3aa2d0fef05a3be1d67a459fb13ab6d9861b86146487f31321f979c464fc516047b66735ab
diff --git a/dev-python/eyeD3/eyeD3-0.9.6.ebuild b/dev-python/eyeD3/eyeD3-0.9.6.ebuild
deleted file mode 100644
index 8245a9dc9755..000000000000
--- a/dev-python/eyeD3/eyeD3-0.9.6.ebuild
+++ /dev/null
@@ -1,45 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{8..10} )
-
-inherit distutils-r1
-
-DESCRIPTION="Module for manipulating ID3 (v1 + v2) tags in Python"
-HOMEPAGE="https://eyed3.nicfit.net/"
-SRC_URI="https://github.com/nicfit/eyeD3/archive/v${PV}.tar.gz -> ${P}.tar.gz
-	test? ( https://eyed3.nicfit.net/releases/eyeD3-test-data.tgz )"
-
-LICENSE="GPL-2"
-SLOT="0.7"
-KEYWORDS="amd64 arm ~arm64 ~hppa ~ia64 ppc ppc64 ~riscv sparc x86"
-
-RDEPEND="
-	dev-python/deprecation[${PYTHON_USEDEP}]
-	dev-python/filetype[${PYTHON_USEDEP}]"
-# note: most of the deps are optional runtime deps / plugin deps
-BDEPEND="
-	test? (
-		dev-python/pillow[${PYTHON_USEDEP}]
-		dev-python/pylast[${PYTHON_USEDEP}]
-		dev-python/ruamel-yaml[${PYTHON_USEDEP}]
-		dev-python/six[${PYTHON_USEDEP}]
-	)"
-
-distutils_enable_tests pytest
-
-src_prepare() {
-	# requires unpackaged factory-boy, doesn't seem to relevant
-	# to anything but eyeD3 usage with factory-boy
-	rm tests/test_factory.py || die
-	# requires unpackaged grako
-	rm tests/test_display_plugin.py || die
-
-	if use test; then
-		mv "${WORKDIR}"/eyeD3-test-data tests/data || die
-	fi
-
-	distutils-r1_src_prepare
-}
diff --git a/dev-python/eyeD3/eyeD3-0.9.7-r1.ebuild b/dev-python/eyeD3/eyeD3-0.9.7-r1.ebuild
new file mode 100644
index 000000000000..af53db71b6cd
--- /dev/null
+++ b/dev-python/eyeD3/eyeD3-0.9.7-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Module for manipulating ID3 (v1 + v2) tags in Python"
+HOMEPAGE="
+	https://eyed3.nicfit.net/
+	https://github.com/nicfit/eyeD3/
+	https://pypi.org/project/eyed3/
+"
+SRC_URI="
+	https://github.com/nicfit/eyeD3/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	test? (
+		https://eyed3.nicfit.net/releases/eyeD3-test-data.tgz
+			-> eyeD3-test-data-r1.tgz
+	)
+"
+
+LICENSE="GPL-2"
+SLOT="0.7"
+KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv sparc x86"
+
+RDEPEND="
+	dev-python/deprecation[${PYTHON_USEDEP}]
+	dev-python/filetype[${PYTHON_USEDEP}]
+	|| (
+		dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)
+"
+# note: most of the deps are optional runtime deps / plugin deps
+BDEPEND="
+	test? (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pylast[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# unpackaged deps
+	tests/test_factory.py
+)
+
+EPYTEST_DESELECT=(
+	# broken by formatting / line wrapping
+	tests/test_jsonyaml_plugin.py::testYamlPlugin
+)
+
+src_prepare() {
+	if use test; then
+		mv "${WORKDIR}"/eyeD3-test-data tests/data || die
+	fi
+
+	# don't install everything to site-packages
+	sed -i -e '/^include = /,/\]/d' pyproject.toml || die
+	# optional without putting it in extra group == non-optional, sigh
+	sed -i -e '/coverage/d' pyproject.toml || die
+
+	distutils-r1_src_prepare
+}