1 files changed, 36 insertions, 0 deletions
diff --git a/dev-python/fitsio/fitsio-1.1.7.ebuild b/dev-python/fitsio/fitsio-1.1.7.ebuild
new file mode 100644
index 000000000000..80ad81b256f8
--- /dev/null
+++ b/dev-python/fitsio/fitsio-1.1.7.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Python library to read from and write to FITS files"
+HOMEPAGE="https://github.com/esheldon/fitsio"
+SRC_URI="
+	https://github.com/esheldon/fitsio/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/numpy-1.11[${PYTHON_USEDEP}]
+	sci-libs/cfitsio:0=
+"
+BDEPEND="${RDEPEND}"
+
+src_prepare() {
+	sed -e '/self.use_system_fitsio/s/False/True/' -i setup.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	cp -r -l -n fitsio "${BUILD_DIR}/lib" || die
+	cd "${BUILD_DIR}/lib" || die
+	${EPYTHON} -c "import fitsio; exit(fitsio.test.test())" || die "Tests failed with ${EPYTHON}"
+}