1 files changed, 42 insertions, 0 deletions
diff --git a/dev-python/icalendar/icalendar-5.0.7.ebuild b/dev-python/icalendar/icalendar-5.0.7.ebuild
new file mode 100644
index 000000000000..531c29848677
--- /dev/null
+++ b/dev-python/icalendar/icalendar-5.0.7.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Package used for parsing and generating iCalendar files (RFC 2445)"
+HOMEPAGE="
+	https://github.com/collective/icalendar/
+	https://pypi.org/project/icalendar/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/backports-zoneinfo[${PYTHON_USEDEP}]
+	' 3.8)
+"
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# reset conf.py to not read version from an installed instance
+	sed -e "s:pkg_resources.get_distribution('icalendar').version:'${PV}':" \
+		-i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}