1 files changed, 51 insertions, 0 deletions
diff --git a/dev-python/jaraco-stream/jaraco-stream-3.0.0.ebuild b/dev-python/jaraco-stream/jaraco-stream-3.0.0.ebuild
new file mode 100644
index 000000000000..48dec9742af4
--- /dev/null
+++ b/dev-python/jaraco-stream/jaraco-stream-3.0.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{6,7,8} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Routines for handling streaming data"
+HOMEPAGE="https://github.com/jaraco/jaraco.stream"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=dev-python/namespace-jaraco-2[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/more-itertools[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_test() {
+	# Skip one test which requires network access
+	# Override pytest options to skip flake8
+	PYTHONPATH=. pytest -vv --ignore=jaraco/stream/test_gzip.py \
+		--override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+# https://wiki.gentoo.org/wiki/Project:Python/Namespace_packages#File_collisions_between_pkgutil-style_packages
+python_install() {
+	rm "${BUILD_DIR}"/lib/jaraco/__init__.py || die
+	# note: eclass may default to --skip-build in the future
+	distutils-r1_python_install --skip-build
+}