3 files changed, 75 insertions, 60 deletions
diff --git a/dev-python/poetry-core/Manifest b/dev-python/poetry-core/Manifest
index 64fbfa17da5b..43ce99e68b9f 100644
--- a/dev-python/poetry-core/Manifest
+++ b/dev-python/poetry-core/Manifest
@@ -1 +1 @@
-DIST poetry-core-1.0.8.gh.tar.gz 414941 BLAKE2B 1f663d927aee1f18a9ff38cbf95809538bf9c9e8079d040c240fbc1ffa9e492c6fd20c69f89ddf7e68ddea05beee3b909fdee02e93f47437fffa687dc492ec9a SHA512 6dfed1e1124c37a5f0ec535ede8848e25466da3df6fa6629f6330ce32f05a4d82725d64407e5bcf294d6e467b52966642505ee29f563d3794c4e7aca78045285
+DIST poetry-core-1.9.0.gh.tar.gz 371033 BLAKE2B 67e4674bcc45f6ce1737a26d8f1fd1ce6e6469d692cabe461fb2959b03ab3ca26b9e3848d9cbf533c5fd9bf7d75ac8b70a6aad0cce1930472971cc1ad530aedf SHA512 a2d63480f0df36fabe61c234377a4fa9ea0a1ddce449006162d6e49e849c92ad9c77d0a93aba7c51561bac16a77d5db00a95594bd5e2de328e1664f3f41f689b
diff --git a/dev-python/poetry-core/poetry-core-1.0.8.ebuild b/dev-python/poetry-core/poetry-core-1.0.8.ebuild
deleted file mode 100644
index e5d93f22a8f1..000000000000
--- a/dev-python/poetry-core/poetry-core-1.0.8.ebuild
+++ /dev/null
@@ -1,59 +0,0 @@
-# Copyright 2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=standalone
-PYTHON_COMPAT=( pypy3 python3_{8..11} )
-
-inherit distutils-r1
-
-DESCRIPTION="Poetry PEP 517 Build Backend"
-HOMEPAGE="
-	https://github.com/python-poetry/poetry-core/
-	https://pypi.org/project/poetry-core/
-"
-SRC_URI="
-	https://github.com/python-poetry/poetry-core/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
-
-# check inside src/poetry/core/_vendor/vendor.txt
-RDEPEND="
-	dev-python/attrs[${PYTHON_USEDEP}]
-	dev-python/jsonschema[${PYTHON_USEDEP}]
-	dev-python/lark[${PYTHON_USEDEP}]
-	dev-python/packaging[${PYTHON_USEDEP}]
-	dev-python/pyparsing[${PYTHON_USEDEP}]
-	dev-python/pyrsistent[${PYTHON_USEDEP}]
-	dev-python/six[${PYTHON_USEDEP}]
-	dev-python/tomlkit[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-python/pep517[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/virtualenv[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-EPYTEST_DESELECT=(
-	# Those "fail" bacause of glob file path resulting from newer versions
-	# in our tree than vendored. But those don't affect anything.
-	tests/masonry/builders/test_sdist.py::test_default_with_excluded_data
-	tests/masonry/builders/test_wheel.py::test_default_src_with_excluded_data
-)
-
-src_prepare() {
-	# remove vendoring of dependencies
-	rm -r poetry/core/_vendor || die
-	sed -e '/__vendor_site__/d' -i poetry/core/__init__.py || die
-
-	distutils-r1_src_prepare
-}
diff --git a/dev-python/poetry-core/poetry-core-1.9.0.ebuild b/dev-python/poetry-core/poetry-core-1.9.0.ebuild
new file mode 100644
index 000000000000..a89bd637c701
--- /dev/null
+++ b/dev-python/poetry-core/poetry-core-1.9.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( pypy3 python3_{10..13} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+DESCRIPTION="Poetry PEP 517 Build Backend"
+HOMEPAGE="
+	https://github.com/python-poetry/poetry-core/
+	https://pypi.org/project/poetry-core/
+"
+SRC_URI="
+	https://github.com/python-poetry/poetry-core/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~arm64-macos ~x64-macos"
+
+# check inside vendors/pyproject.toml
+# (note that some are indirect deps)
+RDEPEND="
+	>=dev-python/fastjsonschema-2.18.0[${PYTHON_USEDEP}]
+	>=dev-python/lark-1.1.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-22.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/build[${PYTHON_USEDEP}]
+			dev-python/pytest-mock[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20.21[${PYTHON_USEDEP}]
+			dev-vcs/git
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove vendoring of dependencies
+	rm -r src/poetry/core/_vendor || die
+	sed -e '/__vendor_site__/d' -i src/poetry/core/__init__.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# These "fail" bacause of glob file path resulting from newer versions
+		# in our tree than vendored. But those don't affect anything.
+		tests/masonry/builders/test_sdist.py::test_default_with_excluded_data
+		tests/masonry/builders/test_wheel.py::test_default_src_with_excluded_data
+	)
+
+	if ! has "${EPYTHON/./_}" "${PYTHON_TESTED[@]}"; then
+		einfo "Skipping tests on ${EPYTHON} (unported deps)"
+		return
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_mock
+}