1 files changed, 60 insertions, 0 deletions
diff --git a/dev-python/pycairo/pycairo-1.19.1.ebuild b/dev-python/pycairo/pycairo-1.19.1.ebuild
new file mode 100644
index 000000000000..66921d842bbe
--- /dev/null
+++ b/dev-python/pycairo/pycairo-1.19.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{6,7,8} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for the cairo library"
+HOMEPAGE="https://www.cairographics.org/pycairo/ https://github.com/pygobject/pycairo"
+SRC_URI="https://github.com/pygobject/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples test"
+
+BDEPEND="
+	doc? ( $(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]') )
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	>=x11-libs/cairo-1.13.1[svg]
+"
+DEPEND="${RDEPEND}"
+
+RESTRICT="!test? ( test )"
+
+distutils_enable_tests setup.py
+
+python_check_deps() {
+	use doc || return 0
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs -b html _build/html || die
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install \
+		install_pkgconfig --pkgconfigdir="${EPREFIX}/usr/$(get_libdir)/pkgconfig"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( _build/html/. )
+
+	if use examples; then
+		dodoc -r examples
+	fi
+
+	distutils-r1_python_install_all
+}